Initial import

2 files changed, 81 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3d113eba5420
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = opengv-git
+	pkgdesc = An efficient C++ library for calibrated camera pose computation using geometric computer vision algorithms.
+	pkgver = r85.02697d3
+	pkgrel = 1
+	url = https://laurentkneip.github.io/opengv/
+	arch = i686
+	arch = x86_64
+	license = BSD
+	makedepends = boost
+	makedepends = cmake
+	makedepends = git
+	depends = boost-libs
+	depends = eigen>=3
+	depends = python2
+	provides = opengv
+	conflicts = opengv
+	source = opengv::git+https://github.com/laurentkneip/opengv.git
+	md5sums = SKIP
+
+pkgname = opengv-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1790444af77c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: Forest Crossman <cyrozap at gmail dot com>
+
+pkgname=opengv-git
+pkgver=r85.02697d3
+pkgrel=1
+pkgdesc="An efficient C++ library for calibrated camera pose computation using geometric computer vision algorithms."
+arch=('i686' 'x86_64')
+url="https://laurentkneip.github.io/opengv/"
+license=('BSD')
+depends=('boost-libs' 'eigen>=3' 'python2')
+makedepends=('boost' 'cmake' 'git')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("${pkgname%-git}::git+https://github.com/laurentkneip/opengv.git")
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	cd "$srcdir/${pkgname%-git}"
+
+	[ ! -d build ] || rm -r build
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}"
+
+	mkdir build
+	cd build
+	cmake .. \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DBUILD_SHARED_LIBS=ON \
+		-DBUILD_PYTHON=ON \
+		-DBUILD_POSITION_INDEPENDENT_CODE=ON \
+		-DINSTALL_OPENGV=ON
+	make
+}
+
+check() {
+	cd "$srcdir/${pkgname%-git}"
+
+	cd build/bin
+	for test in test_*; do
+		./$test
+	done
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}"
+
+	install -d "$pkgdir/usr/share/licenses/$pkgname/"
+	install -m 644 License.txt "$pkgdir/usr/share/licenses/$pkgname/"
+
+	cd build
+	make DESTDIR="$pkgdir/" install
+}