Initial commit.

Branched from openscad-git using jordanbrown0's experimental branch.

3 files changed, 99 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a2b17d3b199f
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,31 @@
+pkgbase = openscad-objects-git
+	pkgdesc = The programmers solid 3D CAD modeller with experimental support for user-defined objects
+	pkgver = 2019.05.r2568.gccce0d16f
+	pkgrel = 1
+	url = https://github.com/jordanbrown0/openscad
+	arch = x86_64
+	license = GPL2
+	makedepends = git
+	makedepends = boost
+	makedepends = cmake
+	makedepends = eigen
+	makedepends = imagemagick
+	makedepends = python
+	makedepends = flex
+	makedepends = bison
+	depends = boost-libs
+	depends = cgal
+	depends = libzip
+	depends = opencsg
+	depends = qscintilla-qt5
+	depends = qt5-base
+	depends = qt5-gamepad
+	depends = qt5-multimedia
+	depends = qt5-svg
+	depends = tbb
+	provides = openscad
+	conflicts = openscad
+	source = openscad::git+https://github.com/jordanbrown0/openscad#branch=objects,geometry-as-data,module-references
+	sha256sums = SKIP
+
+pkgname = openscad-objects-git
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..5099a5aa9d35
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+pkg/
+src/
+openscad/
+*.pkg.tar.zst
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..efe67695b624
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,64 @@
+# Maintainer: Thomas Flucke <tflucke@protonmail.com>
+# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: Kyle Keen <keenerd@gmail.com>
+# Contributor: Torsten Wagner <tottiwagner@yahoo.de>
+
+pkgname=openscad-objects-git
+_pkg="${pkgname%-objects-git}"
+pkgver=2019.05.r2568.gccce0d16f
+pkgrel=1
+pkgdesc="The programmers solid 3D CAD modeller with experimental support for user-defined objects"
+arch=('x86_64')
+license=('GPL2')
+url='https://github.com/jordanbrown0/openscad'
+_branch="objects,geometry-as-data,module-references"
+provides=("$_pkg")
+conflicts=("$_pkg")
+depends=(
+	'boost-libs'
+	'cgal'
+	'libzip'
+	'opencsg'
+	'qscintilla-qt5'
+	'qt5-base'
+	'qt5-gamepad'
+	'qt5-multimedia'
+	'qt5-svg'
+	'tbb')
+makedepends=('git' 'boost' 'cmake' 'eigen' 'imagemagick' 'python' 'flex' 'bison')
+source=("$_pkg::git+$url#branch=$_branch")
+sha256sums=('SKIP')
+
+pkgver() {
+	git -C "$_pkg" describe --long --tags | sed 's/^openscad-//;s/-/.r/;s/-/./'
+}
+
+prepare() {
+	cd "$_pkg"
+	sed -i 's/ping files.openscad.org/ping archlinux.org/' resources/CMakeLists.txt
+	git submodule update --init --recursive
+    cd submodules/mimalloc
+    git checkout v1.8.2 
+}
+
+build() {
+	cmake \
+		-B build \
+		-S "$_pkg" \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DCMAKE_BUILD_TYPE=None \
+		-DEXPERIMENTAL=ON \
+		-DOFFLINE_DOCS=ON \
+		-Wno-dev
+	cmake --build build
+	cd "$_pkg/resources/icons/"
+	convert openscad.png -resize 128x128\> openscad-128.png
+}
+
+package() {
+	DESTDIR="$pkgdir" cmake --install build
+	cd "$_pkg"
+	install -Dm644 "resources/icons/openscad.desktop" "$pkgdir/usr/share/applications/openscad.desktop"
+	install -Dm644 "resources/icons/openscad-128.png" "$pkgdir/usr/share/pixmaps/openscad.png"
+}
+