initial commit

4 files changed, 84 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3b92e7d058bb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = pangolin-desktop-git
+	pkgdesc = Pangolin Desktop UI shell, designed for dahliaOS, written in Flutter.
+	pkgver = r1339.b10860d
+	pkgrel = 1
+	url = https://github.com/dahlia-os/pangolin-desktop
+	arch = x86_64
+	license = Apache
+	makedepends = git
+	makedepends = flutter
+	makedepends = cmake
+	makedepends = ninja
+	makedepends = imagemagick
+	depends = gtk3
+	provides = pangolin-desktop
+	conflicts = pangolin-desktop
+	source = git+https://github.com/dahlia-os/pangolin-desktop.git
+	source = pangolin-desktop.desktop
+	sha256sums = SKIP
+	sha256sums = f9b790200ac34e3dc038b0bc3366d91c08239762466ccc383fc2eb8f03ad2c02
+
+pkgname = pangolin-desktop-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..0f59accca532
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,8 @@
+# Ignore everything
+*
+
+# But not these files...
+!.gitignore
+!PKGBUILD
+!.SRCINFO
+!pangolin-desktop.desktop
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..fff8163d040b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Mark Wagie <mark dot wagie at tutanota dot com>
+pkgname=pangolin-desktop-git
+pkgver=r1339.b10860d
+pkgrel=1
+pkgdesc="Pangolin Desktop UI shell, designed for dahliaOS, written in Flutter."
+arch=('x86_64')
+url="https://github.com/dahlia-os/pangolin-desktop"
+license=('Apache')
+depends=('gtk3')
+makedepends=('git' 'flutter' 'cmake' 'ninja' 'imagemagick')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=('git+https://github.com/dahlia-os/pangolin-desktop.git'
+        "${pkgname%-git}.desktop")
+sha256sums=('SKIP'
+            'f9b790200ac34e3dc038b0bc3366d91c08239762466ccc383fc2eb8f03ad2c02')
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}"
+	flutter channel master
+	flutter upgrade
+	flutter config --enable-linux-desktop
+	flutter build linux
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}/build/linux/release/bundle"
+	install -d "$pkgdir/opt/${pkgname%-git}"
+	cp -r * "$pkgdir/opt/${pkgname%-git}"
+
+	install -d "$pkgdir/usr/bin"
+	ln -s "/opt/${pkgname%-git}/pangolin_desktop" "$pkgdir/usr/bin/${pkgname%-git}"
+
+	convert \
+		data/flutter_assets/assets/images/logos/dahliaOS/PNG/dahliaOS_logo.png \
+		-resize 1024 "$srcdir/dahliaOS_logo-1024.png"
+	install -Dm644 "$srcdir/dahliaOS_logo-1024.png" \
+		"$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
+
+	install -Dm644 "$srcdir/${pkgname%-git}.desktop" -t "$pkgdir/usr/share/applications"
+}
diff --git a/pangolin-desktop.desktop b/pangolin-desktop.desktop
new file mode 100755
index 000000000000..7853de598be9
--- /dev/null
+++ b/pangolin-desktop.desktop
@@ -0,0 +1,8 @@
+[Desktop Entry]
+Type=Application
+Icon=pangolin-desktop
+Name=Pangolin Desktop
+Exec=/opt/pangolin-desktop/pangolin_desktop
+Terminal=false
+Hidden=false
+Comment=Pangolin Desktop UI shell