init

2 files changed, 89 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5010ac540783
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,33 @@
+pkgbase = pdal-git
+	pkgdesc = A C++ library for translating and manipulating point cloud data.
+	pkgver = 1.7.1.r249.g504208055
+	pkgrel = 1
+	url = http://www.pdal.io
+	arch = x86_64
+	license = BSD
+	makedepends = cmake
+	makedepends = python
+	makedepends = python-numpy
+	makedepends = git
+	makedepends = sqlite
+	makedepends = postgresql-libs
+	makedepends = pcl
+	makedepends = laszip
+	depends = gdal
+	depends = geos
+	depends = libgeotiff
+	optdepends = python-numpy: for the Python plugin
+	optdepends = libxml2: for using the database drivers
+	optdepends = sqlite: for the sqlite plugin
+	optdepends = postgresql-libs: for the postgresql plugin
+	optdepends = pcl: for PointCloudLibrary algorithms
+	optdepends = laszip: for LASzip compression
+	optdepends = laz-perf: an alternative LAZ implementation
+	optdepends = jsoncpp: for JSON pipelines
+	provides = pdal
+	conflicts = pdal
+	source = git+https://github.com/PDAL/PDAL
+	sha512sums = SKIP
+
+pkgname = pdal-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d14be9c222c9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: sedot <aur at fry dot fastmail dot com>
+# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
+_name=PDAL
+pkgname=pdal-git
+pkgver=1.7.1.r249.g504208055
+pkgrel=1
+pkgdesc="A C++ library for translating and manipulating point cloud data."
+arch=('x86_64')
+url="http://www.pdal.io"
+license=('BSD')
+depends=('gdal' 'geos' 'libgeotiff')
+makedepends=('cmake' 'python' 'python-numpy' 'git' 'sqlite' 'postgresql-libs' 'pcl' 'laszip')
+optdepends=('python-numpy: for the Python plugin'
+            'libxml2: for using the database drivers'
+            'sqlite: for the sqlite plugin'
+            'postgresql-libs: for the postgresql plugin'
+            'pcl: for PointCloudLibrary algorithms'
+            'laszip: for LASzip compression'
+            'laz-perf: an alternative LAZ implementation'
+            'jsoncpp: for JSON pipelines')
+provides=('pdal')
+conflicts=('pdal')
+source=("git+https://github.com/PDAL/PDAL")
+sha512sums=('SKIP')
+
+pkgver() {
+    cd ${srcdir}/${_name}
+    git describe --long --tags | sed -r 's/^v//;s/([^-]*-g)/r\1/;s/-/./g'
+}
+
+build() {
+    cd ${srcdir}/${_name}
+
+    mkdir -p build && cd build
+
+    cmake .. \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DBUILD_PLUGIN_PYTHON=ON \
+        -DBUILD_PLUGIN_PGPOINTCLOUD=ON \
+        -DBUILD_PLUGIN_SQLITE=ON \
+        -DBUILD_PLUGIN_PCL=ON \
+        -DWITH_LAZPERF=ON \
+        -DWITH_LASZIP=ON \
+        -DWITH_COMPLETION=ON
+        #-DRiVLib_DIR=
+        #-DBUILD_PLUGIN_RIVLIB=ON
+
+    make -j $(nproc --all)
+}
+
+package() {
+    cd ${srcdir}/${_name}/build
+
+    make DESTDIR="$pkgdir/" install
+    install -Dm644 ../LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}