Clean PKGBUILD in lines with packaging guidelines

2 files changed, 25 insertions, 21 deletions

diff --git a/.SRCINFO b/.SRCINFO
index a3a682e4fc73..c73c640068f7 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,18 +1,18 @@
 pkgbase = pdfquirk-git
 	pkgdesc = Create PDFs from images or scanner
-	pkgver = continuous.r0.g0d79759
-	pkgrel = 1
+	pkgver = r35.0d79759
+	pkgrel = 2
 	url = https://dragotin.github.io/quirksite/
 	arch = x86_64
 	license = GPL3
 	makedepends = extra-cmake-modules
+	makedepends = git
 	makedepends = glu
-	makedepends = qt5-base
-	depends = git
+	depends = hicolor-icon-theme
 	depends = imagemagick
+	depends = qt5-base
 	optdepends = sane: scanning support
 	provides = pdfquirk
-	conflicts = pdfquirk
 	source = git+https://github.com/dragotin/pdfquirk.git
 	sha256sums = SKIP
 
diff --git a/PKGBUILD b/PKGBUILD
index 6188b9481c52..49188d1eb58a 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,33 +2,37 @@
 
 _pkgname=pdfquirk
 pkgname=${_pkgname}-git
-pkgver=continuous.r0.g0d79759
-pkgrel=1
-pkgdesc="Create PDFs from images or scanner"
+pkgver=r35.0d79759
+pkgrel=2
+pkgdesc='Create PDFs from images or scanner'
 arch=('x86_64')
-url="https://dragotin.github.io/quirksite/"
+url='https://dragotin.github.io/quirksite/'
 license=('GPL3')
-source=("git+https://github.com/dragotin/${_pkgname}.git")
-depends=('git' 'imagemagick')
+depends=('hicolor-icon-theme' 'imagemagick' 'qt5-base')
+makedepends=('extra-cmake-modules' 'git' 'glu')
 optdepends=('sane: scanning support')
-makedepends=('extra-cmake-modules' 'glu' 'qt5-base')
 provides=("${_pkgname}")
-conflicts=("${_pkgname}")
+source=("git+https://github.com/dragotin/${_pkgname}.git")
 sha256sums=('SKIP')
 
 pkgver() {
   cd "${_pkgname}"
-  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
 }
 
 build() {
-  cd "${_pkgname}"
-  cmake . -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr
+  export CFLAGS+=" ${CPPFLAGS}"
+  export CXXFLAGS+=" ${CPPFLAGS}"
+  cmake -B build -S "${_pkgname}" \
+    -DCMAKE_BUILD_TYPE='None' \
+    -DCMAKE_INSTALL_PREFIX='/usr' \
+    -Wno-dev
+  make -C build
 }
 
 package() {
-  cd "${_pkgname}"
-  make DESTDIR=${pkgdir} install
-  install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
-  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
-}
\ No newline at end of file
+  make DESTDIR="${pkgdir}" PREFIX="/usr" -C build install
+  install -Dm644 "${_pkgname}/README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+}
+
+# vim: ts=2 sw=2 et:
\ No newline at end of file