Initial commit

2 files changed, 89 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..08ce2b7da666
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,40 @@
+pkgbase = picom-git
+	pkgdesc = X compositor (fork of compton) (git-version)
+	pkgver = 1242_Next.114.g43b2173_2019.10.23
+	pkgrel = 1
+	url = https://github.com/yshui/compton
+	arch = i686
+	arch = x86_64
+	license = MIT
+	license = MPL2
+	makedepends = git
+	makedepends = mesa
+	makedepends = meson
+	makedepends = asciidoc
+	makedepends = uthash
+	depends = libgl
+	depends = libev
+	depends = pcre
+	depends = libx11
+	depends = xcb-util-renderutil
+	depends = libxcb
+	depends = xcb-util-image
+	depends = libxext
+	depends = pixman
+	depends = libconfig
+	depends = libdbus
+	depends = hicolor-icon-theme
+	depends = libxdg-basedir
+	optdepends = dbus: To control picom via D-Bus
+	optdepends = xorg-xwininfo: For picom-trans
+	optdepends = xorg-xprop: For picom-trans
+	optdepends = python: For picom-convgen.py
+	provides = compton
+	provides = picom
+	conflicts = compton
+	conflicts = picom
+	source = git+https://github.com/yshui/compton.git#branch=next
+	md5sums = SKIP
+
+pkgname = picom-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5262f992fe4c
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: WorMzy Tykashi <wormzy.tykashi@gmail.com>
+# Contributor: OK100 <ok100 at lavabit dot com>
+# Contributor: Valère Monseur <valere dot monseur at ymail dot com>
+
+pkgname=picom-git
+_gitname=compton
+pkgver=1242_Next.114.g43b2173_2019.10.23
+pkgrel=1
+pkgdesc="X compositor (fork of compton) (git-version)"
+arch=(i686 x86_64)
+url="https://github.com/yshui/${_gitname}"
+license=('MIT' 'MPL2')
+depends=('libgl' 'libev' 'pcre' 'libx11' 'xcb-util-renderutil' 'libxcb' 'xcb-util-image' 'libxext'
+         'pixman' 'libconfig' 'libdbus' 'hicolor-icon-theme' 'libxdg-basedir')
+makedepends=('git' 'mesa' 'meson' 'asciidoc' 'uthash')
+optdepends=('dbus:          To control picom via D-Bus'
+            'xorg-xwininfo: For picom-trans'
+            'xorg-xprop:    For picom-trans'
+            'python:        For picom-convgen.py')
+provides=('compton' 'picom')
+conflicts=('compton' 'picom')
+source=(git+"https://github.com/yshui/${_gitname}.git#branch=next")
+md5sums=("SKIP")
+
+pkgver() {
+    cd ${_gitname}
+    _tag=$(git describe --tags | sed 's:^v::') # tag is mobile, and switches between numbers and letters, can't use it for versioning
+    _commits=$(git rev-list --count HEAD) # total commits is the most sane way of getting incremental pkgver
+    _date=$(git log -1 --date=short --pretty=format:%cd)
+    printf "%s_%s_%s\n" "${_commits}" "${_tag}" "${_date}" | sed 's/-/./g'
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  meson --buildtype=release . build --prefix=/usr -Dbuild_docs=true
+  ninja -C build
+}
+
+package() {
+  cd "${srcdir}/${_gitname}"
+
+  DESTDIR="${pkgdir}" ninja -C build install
+
+  # install license
+  install -D -m644 "LICENSES/MIT" "${pkgdir}/usr/share/licenses/${pkgname/-git$/}/LICENSE-MIT"
+
+  # example conf
+  install -D -m644 "picom.sample.conf" "${pkgdir}/etc/xdg/picom.conf.example"
+}