initial commit

2 files changed, 96 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..13ae5d1c86c0
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,47 @@
+pkgbase = picom-ibhagwan-git
+	pkgdesc = iBhagwan's compton|picom fork (X compositor) with dual_kawase blur and rounded corners
+	pkgver = 1379_Next.98.g68c8f1b_2020.04.26
+	pkgrel = 1
+	url = https://github.com/ibhagwan/picom
+	arch = i686
+	arch = x86_64
+	license = MIT
+	license = MPL2
+	makedepends = git
+	makedepends = mesa
+	makedepends = meson
+	makedepends = asciidoc
+	makedepends = uthash
+	depends = libgl
+	depends = libev
+	depends = pcre
+	depends = libx11
+	depends = xcb-util-renderutil
+	depends = libxcb
+	depends = xcb-util-image
+	depends = libxext
+	depends = pixman
+	depends = libconfig
+	depends = libdbus
+	depends = hicolor-icon-theme
+	depends = libxdg-basedir
+	optdepends = dbus: To control picom via D-Bus
+	optdepends = xorg-xwininfo: For picom-trans
+	optdepends = xorg-xprop: For picom-trans
+	optdepends = python: For picom-convgen.py
+	provides = compton
+	provides = compton-git
+	provides = picom
+	provides = picom-git
+	conflicts = compton
+	conflicts = compton-git
+	conflicts = picom
+	conflicts = picom-git
+	replaces = compton-git
+	replaces = picom-git
+	options = !strip
+	source = git+https://github.com/ibhagwan/picom.git
+	md5sums = SKIP
+
+pkgname = picom-ibhagwan-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0d67f815a68a
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: iBhagwan <bhagwan at disroot dot org>
+
+pkgname=picom-ibhagwan-git
+_gitname=picom
+pkgver=1379_Next.98.g68c8f1b_2020.04.26
+pkgrel=1
+pkgdesc="iBhagwan's compton|picom fork (X compositor) with dual_kawase blur and rounded corners"
+arch=(i686 x86_64)
+url="https://github.com/ibhagwan/${_gitname}"
+license=('MIT' 'MPL2')
+depends=('libgl' 'libev' 'pcre' 'libx11' 'xcb-util-renderutil' 'libxcb' 'xcb-util-image' 'libxext'
+         'pixman' 'libconfig' 'libdbus' 'hicolor-icon-theme' 'libxdg-basedir')
+makedepends=('git' 'mesa' 'meson' 'asciidoc' 'uthash')
+optdepends=('dbus:          To control picom via D-Bus'
+            'xorg-xwininfo: For picom-trans'
+            'xorg-xprop:    For picom-trans'
+            'python:        For picom-convgen.py')
+provides=('compton' 'compton-git' 'picom' 'picom-git')
+conflicts=('compton' 'compton-git' 'picom' 'picom-git')
+replaces=('compton-git' 'picom-git')
+options=('!strip')
+source=(git+"https://github.com/ibhagwan/${_gitname}.git")
+md5sums=("SKIP")
+
+pkgver() {
+    cd ${_gitname}
+    _tag=$(git describe --tags | sed 's:^v::') # tag is mobile, and switches between numbers and letters, can't use it for versioning
+    _commits=$(git rev-list --count HEAD) # total commits is the most sane way of getting incremental pkgver
+    _date=$(git log -1 --date=short --pretty=format:%cd)
+    printf "%s_%s_%s\n" "${_commits}" "${_tag}" "${_date}" | sed 's/-/./g'
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  meson --buildtype=release . build --prefix=/usr -Dwith_docs=true
+  ninja -C build
+}
+
+package() {
+  cd "${srcdir}/${_gitname}"
+
+  DESTDIR="${pkgdir}" ninja -C build install
+
+  # install license
+  install -D -m644 "LICENSES/MIT" "${pkgdir}/usr/share/licenses/${pkgname/-git$/}/LICENSE-MIT"
+
+  # example conf
+  install -D -m644 "picom.sample.conf" "${pkgdir}/etc/xdg/picom.conf.example"
+}