Package added

2 files changed, 54 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9758d7858572
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = plasmatube-git
+	pkgdesc = Kirigami YouTube video player based on libmpv and youtube-dl
+	pkgver = r60.630fd5e
+	pkgrel = 1
+	url = https://invent.kde.org/lnj/plasmatube
+	arch = x86_64
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	makedepends = extra-cmake-modules
+	depends = ki18n
+	depends = kirigami2
+	depends = qt5-svg
+	depends = youtube-dl
+	depends = mpv
+	provides = plasmatube
+	conflicts = plasmatube
+	source = git+https://invent.kde.org/lnj/plasmatube.git
+	sha256sums = SKIP
+
+pkgname = plasmatube-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..ef176bf40149
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: Gustavo Castro < gustawho [ at ] gmail [ dot ] com >
+
+pkgname=plasmatube-git
+pkgver=r60.630fd5e
+pkgrel=1
+pkgdesc="Kirigami YouTube video player based on libmpv and youtube-dl"
+arch=(x86_64 aarch64)
+url="https://invent.kde.org/lnj/plasmatube"
+license=(GPL3)
+depends=('ki18n' 'kirigami2' 'qt5-svg' 'youtube-dl' 'mpv')
+makedepends=('git' 'extra-cmake-modules')
+provides=('plasmatube')
+conflicts=('plasmatube')
+source=("git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+build() {
+  cmake -DCMAKE_INSTALL_PREFIX=/usr -B build -S "${pkgname%-git}"
+  make -C build
+}
+
+package() {
+  make -C build DESTDIR="${pkgdir}" PREFIX=/usr install
+}