Initial import

4 files changed, 126 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3c9c8a829d79
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,32 @@
+pkgbase = popcorntime-git
+	pkgdesc = Stream movies from torrents. Skip the downloads. Launch, click, watch.
+	pkgver = r4591.101f883
+	pkgrel = 1
+	url = http://popcorntime.io
+	install = popcorntime.install
+	arch = i686
+	arch = x86_64
+	license = GPL3
+	makedepends = git
+	makedepends = nodejs-grunt-cli
+	makedepends = nodejs-bower
+	makedepends = npm
+	depends = alsa-lib
+	depends = gconf
+	depends = gtk2
+	depends = nss
+	depends = ttf-liberation
+	depends = libxtst
+	optdepends = net-tools: vpn.ht client
+	provides = popcorntime
+	conflicts = popcorntime
+	options = !strip
+	source = popcorntime.install
+	source = git+https://git.popcorntime.io/popcorntime/desktop.git
+	source = popcorntime.desktop
+	md5sums = efe872f41ed74a706308b4015e4fd82f
+	md5sums = SKIP
+	md5sums = 9608f35f4cc083a0c36b0f4ef275ab10
+
+pkgname = popcorntime-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..997d3f12d6b0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,74 @@
+# Contributor: Eric Engestrom <aur [at] engestrom [dot] ch>
+# Contributor: Attila Bukor <r1pp3rj4ck [at] w4it [dot] eu>
+
+pkgname=popcorntime-git
+pkgver=r4591.101f883
+pkgrel=1
+pkgdesc="Stream movies from torrents. Skip the downloads. Launch, click, watch."
+arch=('i686' 'x86_64')
+url="http://popcorntime.io"
+license=('GPL3')
+depends=('alsa-lib' 'gconf' 'gtk2' 'nss' 'ttf-liberation' 'libxtst')
+optdepends=('net-tools: vpn.ht client')
+makedepends=('git' 'nodejs-grunt-cli' 'nodejs-bower' 'npm')
+conflicts=('popcorntime')
+provides=('popcorntime')
+options=('!strip')
+install="popcorntime.install"
+
+[ "$CARCH" = "i686" ]   && _platform=linux32
+[ "$CARCH" = "x86_64" ] && _platform=linux64
+_gitname=desktop
+
+source=('popcorntime.install'
+        "git+https://git.popcorntime.io/popcorntime/desktop.git"
+        "popcorntime.desktop")
+md5sums=('efe872f41ed74a706308b4015e4fd82f'
+         'SKIP'
+         '9608f35f4cc083a0c36b0f4ef275ab10')
+
+pkgver() {
+  cd "${srcdir}/${_gitname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${srcdir}/${_gitname}"
+
+  export PYTHON=/usr/bin/python2
+
+  # Get dependencies
+  npm install
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  grunt build
+}
+
+package() {
+  cd "${srcdir}"
+
+  _bpath="${srcdir}/${_gitname}/build/releases/Popcorn-Time/${_platform}/Popcorn-Time"
+
+  install -d "${pkgdir}/usr/lib/popcorntime"
+  install -d "${pkgdir}/usr/bin"
+
+  # Program
+  install -Dm755 "${_bpath}/Popcorn-Time" "${pkgdir}/usr/lib/popcorntime/"
+  install -Dm644 "${_bpath}/nw.pak" "${pkgdir}/usr/lib/popcorntime/"
+  install -Dm644 "${_bpath}/libffmpegsumo.so" "${pkgdir}/usr/lib/popcorntime/"
+
+  # Link to program
+  mkdir -p "${pkgdir}/usr/bin"
+  ln -s "/usr/lib/popcorntime/Popcorn-Time" "${pkgdir}/usr/bin/popcorntime"
+
+  # Desktop file
+  install -Dm644 "${srcdir}/popcorntime.desktop" "${pkgdir}/usr/share/applications/popcorntime.desktop"
+
+  # Icon
+  install -Dm644 "${srcdir}/${_gitname}/src/app/images/icon.png" "${pkgdir}/usr/share/pixmaps/popcorntime.png"
+}
+
+# vim:set ts=2 sw=2 et:
+
diff --git a/popcorntime.desktop b/popcorntime.desktop
new file mode 100644
index 000000000000..f8f223bc36aa
--- /dev/null
+++ b/popcorntime.desktop
@@ -0,0 +1,8 @@
+[Desktop Entry]
+Name=Popcorn Time
+Comment=Watch torrent movies instantly
+Exec=popcorntime %U
+Icon=popcorntime
+Terminal=false
+Type=Application
+Categories=Player;Video;Network;
diff --git a/popcorntime.install b/popcorntime.install
new file mode 100644
index 000000000000..bd924b2be4a8
--- /dev/null
+++ b/popcorntime.install
@@ -0,0 +1,12 @@
+post_install() {
+  echo
+  echo "WARNING: Popcorn Time streams movies from Torrents"
+  echo "Downloading copyrighted material may be illegal in your country!"
+  echo "Use at your own risk!"
+}
+
+post_upgrade() {
+  post_install
+}
+
+# vim:set ts=2 sw=2 et: