moving this package to aur4/git

3 files changed, 78 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..969c2d02e54d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,27 @@
+pkgbase = printrun-git
+	pkgdesc = Pronterface, Pronsole, and Printcore - Pure Python 3D printing host software and GUI
+	pkgver = 20150310
+	pkgrel = 1
+	url = https://github.com/kliment/Printrun
+	install = printrun-git.install
+	arch = i686
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	makedepends = cython2
+	depends = python2-pyserial
+	depends = wxpython
+	depends = pyglet
+	depends = desktop-file-utils
+	optdepends = python2-cairo: to use Projector feature
+	optdepends = python2-cairosvg: to use Projector feature
+	optdepends = python2-numpy: for 3D view
+	optdepends = python2-dbus: to inhibit sleep when printing
+	optdepends = python2-psutil: to increase process priority when printing
+	provides = printrun
+	conflicts = printrun
+	source = git://github.com/kliment/Printrun.git
+	sha256sums = SKIP
+
+pkgname = printrun-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..22aaced0c09e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,40 @@
+# Contributor: Richard Kakaš <richard.kakas@gmail.com>
+# Contributor: Eric Anderson <ejona86@gmail.com>
+# Maintainer: Dan Panzarella <alsoelp@gmail.com>
+
+pkgname=printrun-git
+_gitname='Printrun'
+pkgver=20150310
+pkgrel=1
+pkgdesc='Pronterface, Pronsole, and Printcore - Pure Python 3D printing host software and GUI'
+arch=('i686' 'x86_64')
+url='https://github.com/kliment/Printrun'
+license=('GPL')
+provides=('printrun')
+conflicts=('printrun')
+depends=('python2-pyserial' 'wxpython' 'pyglet' 'desktop-file-utils')
+optdepends=(
+  'python2-cairo: to use Projector feature'
+  'python2-cairosvg: to use Projector feature'
+  'python2-numpy: for 3D view'
+  'python2-dbus: to inhibit sleep when printing'
+  'python2-psutil: to increase process priority when printing')
+makedepends=('git' 'cython2')
+install="${pkgname}.install"
+source=('git://github.com/kliment/Printrun.git')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_gitname}"
+  git describe --tags --always | sed 's/printrun-//' | sed 's|-|.|g'
+}
+
+build() {
+  cd "${srcdir}/${_gitname}"
+  python2 setup.py build
+}
+
+package() {
+  cd "${srcdir}/${_gitname}"
+  python2 setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+}
diff --git a/printrun-git.install b/printrun-git.install
new file mode 100644
index 000000000000..defd3433ae2c
--- /dev/null
+++ b/printrun-git.install
@@ -0,0 +1,11 @@
+post_install() {
+  post_upgrade
+}
+
+post_upgrade() {
+  update-desktop-database -q
+}
+
+post_remove() {
+  post_upgrade
+}