init

2 files changed, 59 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..1956bced6469
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,13 @@
+pkgbase = projectable-git
+	pkgdesc = A TUI file manager built for projects.
+	pkgver = 1.1.0.2.g0f1e053
+	pkgrel = 1
+	url = https://github.com/dzfrias/projectable
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = cargo
+	source = projectable::git+https://github.com/dzfrias/projectable.git
+	sha256sums = SKIP
+
+pkgname = projectable-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..a70d8e7aa8d5
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Ayoub Canon <imkonnu@gmail.com>
+
+pkgname=projectable-git
+_pkgname=projectable
+_bin=prj
+pkgver=1.1.0.2.g0f1e053
+pkgrel=1
+pkgdesc="A TUI file manager built for projects."
+arch=('x86_64')
+url="https://github.com/dzfrias/projectable"
+_git="https://github.com/dzfrias/projectable.git"
+license=('MIT')
+depends=()
+makedepends=('git' 'cargo')
+source=("${_pkgname}::git+${_git}")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "${_pkgname}"
+    git describe --tags | sed 's/-/./g'
+}
+
+prepare() {
+    cd "$_pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    cargo update
+    cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+    cd "$_pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    export CARGO_TARGET_DIR=target
+    cargo build --frozen --release --all-features
+}
+
+check() {
+    cd "$_pkgname"
+    export RUSTUP_TOOLCHAIN=stable
+    cargo test --frozen --all-features
+}
+
+package() {
+    cd "$_pkgname"
+    install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$_bin"
+}