Init

3 files changed, 93 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7042b366f3ad
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = python-aigpy-git
+	pkgdesc = Python Common Lib
+	pkgver = 20190925.fc958ab
+	pkgrel = 1
+	url = https://github.com/yaronzz/AIGPY
+	arch = any
+	license = MIT
+	makedepends = git
+	makedepends = python-setuptools
+	makedepends = python2-setuptools
+	source = aigpy::git+https://github.com/yaronzz/AIGPY.git
+	sha256sums = SKIP
+
+pkgname = python-aigpy-git
+	depends = python
+	depends = python-requests
+	depends = python-colorama
+	depends = python-mutagen
+
+pkgname = python2-aigpy-git
+	depends = python2
+	depends = python2-requests
+	depends = python2-colorama
+	depends = python2-mutagen
+	depends = python2-futures
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..6b00f30e0e8e
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,6 @@
+aigpy/
+*.log
+pkg/
+src/
+*.pkg.tar.xz
+*.tar.gz
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1791cb4405a2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,61 @@
+# Maintainer: peeweep <peeweep at 0x0 dot ee>
+
+pkgname=('python-aigpy-git' 'python2-aigpy-git')
+_pkgname=aigpy
+pkgver=20190925.fc958ab
+pkgrel=1
+pkgdesc="Python Common Lib"
+arch=('any')
+url="https://github.com/yaronzz/AIGPY"
+license=('MIT')
+makedepends=(
+  'git'
+  'python-setuptools'
+  'python2-setuptools'
+)
+source=("${_pkgname}::git+${url}.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+  git log -1 --format='%cd.%h' --date=short | tr -d -
+}
+
+prepare() {
+  cp -r "${srcdir}/${_pkgname}" "${srcdir}/${_pkgname}-2"
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+  python setup.py build
+
+  cd "${srcdir}/${_pkgname}-2"
+  python2 setup.py build
+}
+
+package_python-aigpy-git() {
+  depends=(
+    'python'
+    'python-requests'
+    'python-colorama'
+    'python-mutagen'
+  )
+  cd "${srcdir}/${_pkgname}"
+  python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+  install -Dm644 "${srcdir}/${_pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+package_python2-aigpy-git() {
+  depends=(
+    'python2'
+    'python2-requests'
+    'python2-colorama'
+    'python2-mutagen'
+    'python2-futures'
+  )
+  cd "${srcdir}/${_pkgname}-2"
+  python2 setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
+  install -Dm644 "${srcdir}/${_pkgname}-2/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
+
+# vim:set ts=2 sw=2 et: