Add package tracking angr git master

2 files changed, 76 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..cba72506ae6b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,39 @@
+pkgbase = python-angr-git
+	pkgdesc = A powerful and user-friendly binary analysis platform
+	pkgver = 8.18.10.25.r9156.a67010c8
+	pkgrel = 1
+	url = https://github.com/angr/angr
+	arch = any
+	license = BSD
+	makedepends = git
+	makedepends = python-setuptools
+	makedepends = make
+	makedepends = gcc
+	depends = python
+	depends = python-sortedcontainers
+	depends = python-cachetools
+	depends = python-capstone
+	depends = python-cooldict
+	depends = python-dpkt
+	depends = python2-futures
+	depends = python-mulpyplexer
+	depends = python-networkx
+	depends = python-progressbar
+	depends = python-rpyc
+	depends = python-cffi
+	depends = python-unicorn
+	depends = python-archinfo-git
+	depends = python-claripy-git
+	depends = python-cle-git
+	depends = python-pyvex-git
+	depends = python-ailment-git
+	depends = python-gitpython
+	depends = python-pycparser
+	depends = python-itanium_demangler
+	provides = python-angr
+	conflicts = python-angr
+	source = python-angr-git::git+https://github.com/angr/angr.git#branch=master
+	md5sums = SKIP
+
+pkgname = python-angr-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0b0678781d6b
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Colin Unger <mastakata 3 at yahoo dot com>
+
+pkgname=python-angr-git
+pkgdesc="A powerful and user-friendly binary analysis platform"
+url="https://github.com/angr/angr"
+pkgver=8.18.10.25.r9156.a67010c8
+pkgrel=1
+arch=('any')
+depends=('python' 'python-sortedcontainers' 'python-cachetools' 'python-capstone' 'python-cooldict' 'python-dpkt' 'python2-futures' 'python-mulpyplexer' 'python-networkx' 'python-progressbar' 'python-rpyc' 'python-cffi' 'python-unicorn' 'python-archinfo-git' 'python-claripy-git' 'python-cle-git' 'python-pyvex-git' 'python-ailment-git' 'python-gitpython' 'python-pycparser' 'python-itanium_demangler')
+makedepends=('git' 'python-setuptools' 'make' 'gcc')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+license=('BSD')
+source=("$pkgname::git+https://github.com/angr/angr.git#branch=master")
+md5sums=('SKIP')
+
+pkgver() {
+	cd "$srcdir/$pkgname"
+
+	regex='[0-9]\+\.[0-9]\+\.[0-9]\+\.[0-9]\+'
+	prefix='ticked version number to'
+	rev_num="$(git rev-list --count HEAD)"
+	version_no="$(git log -n1 --grep "$prefix $regex" --format=tformat:%s | sed "s/$prefix \($regex\)/\1/g")"
+	last_commit="$(git rev-parse --short HEAD)"
+	echo "$version_no.r$rev_num.$last_commit"
+}
+
+build() {
+	cd "$srcdir/$pkgname"
+	python setup.py build
+}
+
+package() {
+	cd "$srcdir/$pkgname"
+	python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}