package cleanup

2 files changed, 22 insertions, 15 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 019cebdd26bb..d7a9303c2843 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,16 +1,19 @@
 pkgbase = python-binary
 	pkgdesc = Easily convert between binary and SI units
 	pkgver = 1.0.0
-	pkgrel = 4
+	pkgrel = 5
 	url = https://github.com/ofek/binary
 	arch = any
 	license = MIT
 	license = APACHE
-	checkdepends = python-pytest-runner
+	checkdepends = python-pytest
 	checkdepends = python-coverage
+	makedepends = python-build
+	makedepends = python-installer
 	makedepends = python-setuptools
+	makedepends = python-wheel
 	depends = python
-	source = https://files.pythonhosted.org/packages/source/b/binary/binary-1.0.0.tar.gz
+	source = python-binary-1.0.0.tar.gz::https://files.pythonhosted.org/packages/source/b/binary/binary-1.0.0.tar.gz
 	source = 001-setup.py.patch
 	sha256sums = 6ec010e58f7331ebc8bc9638dbe6c66d635de60d5818b0723bef4dead0ec28a6
 	sha256sums = f2cd5dc99ca22d9a2fc8a20c2fd7f1f77922338c22085a73a7737ea08dfc955f
diff --git a/PKGBUILD b/PKGBUILD
index cb1b6ff57b77..2c1d95f47432 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,39 +2,43 @@
 # Contributor: Kaizhao Zhang <zhangkaizhao@gmail.com>
 
 pkgname=python-binary
+_pkg="${pkgname#python-}"
 pkgver=1.0.0
-pkgrel=4
+pkgrel=5
 pkgdesc="Easily convert between binary and SI units"
 arch=('any')
 url="https://github.com/ofek/binary"
 license=('MIT' 'APACHE')
 depends=('python')
-makedepends=('python-setuptools')
-checkdepends=('python-pytest-runner' 'python-coverage')
-source=("https://files.pythonhosted.org/packages/source/b/binary/binary-$pkgver.tar.gz"
+makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
+checkdepends=('python-pytest' 'python-coverage')
+source=("$pkgname-$pkgver.tar.gz::https://files.pythonhosted.org/packages/source/${_pkg::1}/$_pkg/$_pkg-$pkgver.tar.gz"
        '001-setup.py.patch')
 sha256sums=('6ec010e58f7331ebc8bc9638dbe6c66d635de60d5818b0723bef4dead0ec28a6'
             'f2cd5dc99ca22d9a2fc8a20c2fd7f1f77922338c22085a73a7737ea08dfc955f')
 
 prepare() {
 	## removes tests directory from installation
-	patch -p1 -d "binary-$pkgver" < 001-setup.py.patch
+	patch -p1 -d "$_pkg-$pkgver" < 001-setup.py.patch
 }
 
 build() {
-	cd "binary-$pkgver"
-	python setup.py build
+	cd "$_pkg-$pkgver"
+	python -m build --wheel --no-isolation
 }
 
 check() {
-	cd "binary-$pkgver"
-	python setup.py pytest
+	cd "$_pkg-$pkgver"
+	pytest -x
 }
 
 package() {
-	cd "binary-$pkgver"
-	PYTHONHASHSEED=0 python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+	cd "$_pkg-$pkgver"
+	PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir/" dist/*.whl
 	install -Dm644 README.rst -t "$pkgdir/usr/share/doc/$pkgname/"
-	install -Dm644 LICENSE-{APACHE,MIT} -t "$pkgdir/usr/share/licenses/$pkgname/"
+	local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
+	install -d "$pkgdir/usr/share/licenses/$pkgname/"
+	ln -s "$_site/$_pkg-$pkgver.dist-info/LICENSE-MIT" "$pkgdir/usr/share/licenses/$pkgname/"
+	ln -s "$_site/$_pkg-$pkgver.dist-info/LICENSE-APACHE" "$pkgdir/usr/share/licenses/$pkgname/"
 }