Add python-booleanoperations-git

2 files changed, 64 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..29549e62d928
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = python-booleanoperations-git
+	pkgdesc = Boolean operations on paths
+	pkgver = 0.9.0.r3.g25f7091
+	pkgrel = 1
+	url = https://github.com/typemytype/booleanOperations
+	arch = any
+	license = MIT
+	checkdepends = python-defcon
+	checkdepends = python-fontpens
+	checkdepends = python-pytest
+	makedepends = python-setuptools-scm
+	makedepends = git
+	depends = python
+	depends = python-pyclipper
+	depends = python-fonttools
+	provides = python-booleanoperations
+	conflicts = python-booleanoperations
+	source = python-booleanoperations-git::git+https://github.com/typemytype/booleanOperations.git
+	sha256sums = SKIP
+
+pkgname = python-booleanoperations-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c25aeff65503
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: taotieren <admin@taotieren.com>
+
+pkgname=python-booleanoperations-git
+pkgver=0.9.0.r3.g25f7091
+pkgrel=1
+pkgdesc='Boolean operations on paths'
+url='https://github.com/typemytype/booleanOperations'
+license=('MIT')
+arch=(any)
+_pydeps=(pyclipper
+         fonttools)
+depends=(python
+         "${_pydeps[@]/#/python-}")
+checkdepends=(python-defcon
+              python-fontpens
+              python-pytest)
+makedepends=(python-setuptools-scm
+             git)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python -m build -wn
+}
+
+check() {
+    cd "$pkgname"
+    PYTHONPATH=Lib pytest tests
+}
+
+package() {
+    cd "$pkgname"
+    python -m installer -d "$pkgdir" dist/*.whl
+}
+