commit cmdln1-git 2.0.0.r1.g55e980c-2

2 files changed, 74 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..2f6189006243
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+# Generated by mksrcinfo v8
+# Mon Jun 27 19:31:39 UTC 2016
+pkgbase = python-cmdln-git
+	pkgdesc = a Python module for easily building good multi-command scripts
+	pkgver = 2.0.0.r1.g55e980c
+	pkgrel = 2
+	url = http://github.com/trentm/cmdln
+	arch = i686
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	depends = python
+	provides = cmdln
+	source = git://github.com/trentm/cmdln.git
+	sha256sums = SKIP
+
+pkgname = python-cmdln-git
+	depends = python
+
+pkgname = python2-cmdln-git
+	depends = python2
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f29923a7fa0e
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: Christian Hesse <mail@eworm.de>
+# Contributor: Mike Redd <mredd@0tue0.com>
+
+pkgbase=python-cmdln-git
+pkgname=(python-cmdln-git python2-cmdln-git)
+pkgver=2.0.0.r1.g55e980c
+pkgrel=2
+pkgdesc='a Python module for easily building good multi-command scripts'
+arch=('i686' 'x86_64')
+url='http://github.com/trentm/cmdln'
+license=('MIT')
+depends=('python')
+makedepends=('git')
+provides=('cmdln')
+source=('git://github.com/trentm/cmdln.git')
+sha256sums=('SKIP')
+
+pkgver() {
+	cd cmdln/
+
+	if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
+		printf '%s.r%s.g%s' \
+			"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
+			"$(git rev-list --count ${GITTAG}..)" \
+			"$(git log -1 --format='%h')"
+	else
+		printf '0.r%s.g%s' \
+			"$(git rev-list --count master)" \
+			"$(git log -1 --format='%h')"
+	fi
+}
+
+
+package_python-cmdln-git() {
+	depends=('python')
+
+	cd cmdln/
+
+	python setup.py build
+
+	python setup.py install --prefix="${pkgdir}"/usr
+}
+
+package_python2-cmdln-git() {
+	depends=('python2')
+
+	cd cmdln/
+
+	python2 setup.py build
+
+	python2 setup.py install --prefix="${pkgdir}"/usr
+}