v1.1.0

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..49cd28402af8
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = python-darkgraylib
+	pkgdesc = Filter linter messages from various Python linters to only those which were caused by recent changes to the code base being linted
+	pkgver = 1.1.0
+	pkgrel = 1
+	url = https://github.com/akaihola/darkgraylib
+	arch = any
+	license = BSD-3-Clause
+	checkdepends = python-pytest
+	checkdepends = python-pygments
+	checkdepends = python-pytest-kwparametrize
+	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	makedepends = python-setuptools
+	depends = python
+	depends = python-toml
+	optdepends = python-pygments: syntax highlighting
+	source = python-darkgraylib::git+https://github.com/akaihola/darkgraylib.git#commit=4413a5234ed8e8c51bf4cf3a3301e5f65fbef965
+	sha256sums = SKIP
+
+pkgname = python-darkgraylib
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..eb305a8b5ca6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: Bao Trinh <qubidt at gmail dot com>
+
+pkgname=python-darkgraylib
+_pkgname="${pkgname#python-}"
+pkgver=1.1.0
+_commit=4413a5234ed8e8c51bf4cf3a3301e5f65fbef965 # tags/v1.1.0
+pkgrel=1
+pkgdesc='Filter linter messages from various Python linters to only those which were caused by recent changes to the code base being linted'
+arch=(any)
+url="https://github.com/akaihola/darkgraylib"
+license=("BSD-3-Clause")
+depends=(
+	'python'
+	'python-toml'
+)
+makedepends=(
+	'git'
+	'python-build'
+	'python-installer'
+	'python-wheel'
+	'python-setuptools'
+)
+checkdepends=(
+	'python-pytest'
+	'python-pygments'
+	'python-pytest-kwparametrize'
+)
+optdepends=('python-pygments: syntax highlighting')
+source=("${pkgname}::git+${url}.git#commit=${_commit}")
+sha256sums=('SKIP')
+
+build() {
+	cd "${pkgname}"
+	python -m build --no-isolation
+}
+
+check() {
+	cd "${pkgname}"
+	PYTHONPATH=src pytest -v "src/${_pkgname}"
+}
+
+package() {
+	cd "${pkgname}"
+	python -m installer -d "${pkgdir}" dist/*.whl
+	install -Dm644 "LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+	install -Dm644 "README.rst" -t "${pkgdir}/usr/share/doc/${pkgname}"
+}