initial commit

2 files changed, 85 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..e6d01af9be61
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,38 @@
+pkgbase = python-engineio3
+	pkgdesc = Python implementation of the Engine.IO realtime server (Ver 3)
+	pkgver = 3.14.2
+	pkgrel = 1
+	url = https://github.com/miguelgrinberg/python-engineio
+	arch = any
+	license = MIT
+	checkdepends = python-mock
+	checkdepends = python-pytest
+	checkdepends = python-pytest-runner
+	makedepends = python-setuptools
+	makedepends = python-sphinx
+	makedepends = python-six
+	makedepends = python-eventlet
+	makedepends = python-aiohttp
+	makedepends = python-tornado
+	makedepends = python-urllib3
+	makedepends = python-websocket-client
+	makedepends = python-gevent
+	makedepends = python-gevent-websocket
+	makedepends = python-websockets
+	depends = python
+	depends = python-six
+	depends = python-urllib3
+	depends = python-websocket-client
+	depends = python-websockets
+	optdepends = python-eventlet: eventlet driver
+	optdepends = python-aiohttp: aiohttp driver
+	optdepends = python-tornado: tornado driver
+	optdepends = python-gevent: gevent driver
+	optdepends = python-gevent-websocket: gevent driver
+	conflicts = python-engineio
+	options = !makeflags
+	source = https://github.com/miguelgrinberg/python-engineio/archive/v3.14.2/python-engineio3-3.14.2.tar.gz
+	sha256sums = 6764678026fb45f62fd9cb03eb6ca3840b47905dc9eccf3fdde64596508b82d5
+
+pkgname = python-engineio3
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cfbd9a3e43fa
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: yjun <jerrysteve1101 at gmail dot com>
+
+pkgname=python-engineio3
+_pkgname=${pkgname%3}
+pkgver=3.14.2
+pkgrel=1
+pkgdesc="Python implementation of the Engine.IO realtime server (Ver 3)"
+arch=('any')
+url="https://github.com/miguelgrinberg/python-engineio"
+license=('MIT')
+depends=('python' 'python-six' 'python-urllib3' 'python-websocket-client' 'python-websockets')
+optdepends=('python-eventlet: eventlet driver'
+            'python-aiohttp: aiohttp driver'
+            'python-tornado: tornado driver'
+            'python-gevent: gevent driver'
+            'python-gevent-websocket: gevent driver')
+makedepends=('python-setuptools' 'python-sphinx' 'python-six' 'python-eventlet' 'python-aiohttp' 'python-tornado'
+             'python-urllib3' 'python-websocket-client' 'python-gevent' 'python-gevent-websocket' 'python-websockets')
+checkdepends=('python-mock' 'python-pytest' 'python-pytest-runner')
+conflicts=("$_pkgname")
+options=('!makeflags')
+source=(https://github.com/miguelgrinberg/python-engineio/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('6764678026fb45f62fd9cb03eb6ca3840b47905dc9eccf3fdde64596508b82d5')
+
+build() {
+  cd ${_pkgname}-${pkgver}
+
+  python setup.py build
+  make -C docs man text SPHINXBUILD=sphinx-build
+}
+
+check() {
+  cd ${_pkgname}-${pkgver}
+
+  python setup.py test
+}
+
+package() {
+  cd ${_pkgname}-${pkgver}
+
+  python setup.py install -O1 --root="${pkgdir}" --skip-build
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 docs/_build/man/python-engineio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
+}
+# vim: ts=2 sw=2 et: