upgpkg: python-fastdtw 0.3.4-2

2 files changed, 30 insertions, 19 deletions

diff --git a/.SRCINFO b/.SRCINFO
index b84143c38603..e31a977a0e7b 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,15 +1,18 @@
 pkgbase = python-fastdtw
 	pkgdesc = Python implementation of FastDTW
 	pkgver = 0.3.4
-	pkgrel = 1
+	pkgrel = 2
 	url = https://github.com/slaypni/fastdtw
 	arch = x86_64
 	license = MIT
-	checkdepends = python-pytest-runner
-	makedepends = python-setuptools
+	checkdepends = python-pytest
 	makedepends = cython
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-setuptools
+	makedepends = python-wheel
 	depends = python-numpy
 	source = python-fastdtw-0.3.4.tar.gz::https://github.com/slaypni/fastdtw/archive/v0.3.4.tar.gz
-	sha256sums = da9bea6a9bc3c3a3424de1d82d3ce7d0545514ed255af16558ef4ddce28f36a7
+	b2sums = e3a1e630b615c1e074eb7cfa85d3b3173af3a8cde84a29a4454839a42a349212b638709c2af47aec48cdb3fb52c26282bbdf7c5b0f01de17bdd1c660f66c06b8
 
 pkgname = python-fastdtw
diff --git a/PKGBUILD b/PKGBUILD
index 9c7bc91865b8..bcd7a64d5b23 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,34 +1,42 @@
-# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Maintainer: Iyán Méndez Veiga <me (at) iyanmv (dot) com>
+# Contributor: Luis Martinez <luis dot martinez at disroot dot org>
 # Contributor: Conrad Sachweh <conrad+aur@spamthis.space>
-
 pkgname=python-fastdtw
 _name="${pkgname#python-}"
 pkgver=0.3.4
-pkgrel=1
+pkgrel=2
 pkgdesc="Python implementation of FastDTW"
 url="https://github.com/slaypni/fastdtw"
 arch=('x86_64')
 license=('MIT')
 depends=('python-numpy')
-makedepends=('python-setuptools' 'cython')
-checkdepends=('python-pytest-runner')
+makedepends=(
+    'cython'
+    'python-build'
+    'python-installer'
+    'python-setuptools'
+    'python-wheel'
+)
+checkdepends=('python-pytest')
 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
-sha256sums=('da9bea6a9bc3c3a3424de1d82d3ce7d0545514ed255af16558ef4ddce28f36a7')
+b2sums=('e3a1e630b615c1e074eb7cfa85d3b3173af3a8cde84a29a4454839a42a349212b638709c2af47aec48cdb3fb52c26282bbdf7c5b0f01de17bdd1c660f66c06b8')
 
 build() {
-	cd "$_name-$pkgver"
-	python setup.py build
+    cd "$_name-$pkgver"
+    python -m build --wheel --no-isolation
 }
 
 check() {
-	cd "$_name-$pkgver"
-	local _ver="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
-	PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_ver" python setup.py pytest
+    cd "${_name}-${pkgver}"
+    python -m installer --destdir="$srcdir/test" dist/*.whl
+    local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+    export PYTHONPATH="$srcdir"/test/usr/lib/python${python_version}/site-packages
+    pytest -v tests
 }
 
 package() {
-	cd "$_name-$pkgver"
-	python setup.py install --root="${pkgdir}/" --optimize=1 --skip-build
-	install -D LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
-	install -D README.rst -t "$pkgdir/usr/share/doc/$pkgname/"
+    cd "$_name-$pkgver"
+    python -m installer --destdir="$pkgdir" dist/*.whl
+    install -D -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+    install -D -m644 README.rst "$pkgdir/usr/share/doc/$pkgname/README"
 }