Drop Python 2 support

2 files changed, 14 insertions, 46 deletions

diff --git a/.SRCINFO b/.SRCINFO
index a245459483b0..edda572605a6 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,27 +1,19 @@
 pkgbase = python-mbdata-git
 	pkgdesc = MusicBrainz database tools for Python
-	pkgver = 25.0.0.r0.g384f8ab
+	pkgver = 25.0.4.r3.g5d8cadf
 	pkgrel = 1
 	url = https://github.com/lalinsky/mbdata
 	arch = any
 	license = MIT
 	makedepends = python-setuptools
-	makedepends = python2-setuptools
 	makedepends = git
-	source = git+https://github.com/lalinsky/mbdata.git
-	sha256sums = SKIP
-
-pkgname = python-mbdata-git
 	depends = python
 	depends = python-psycopg2
 	depends = python-six
 	provides = python-mbdata
 	conflicts = python-mbdata
+	source = git+https://github.com/lalinsky/mbdata.git
+	sha256sums = SKIP
 
-pkgname = python2-mbdata-git
-	depends = python2
-	depends = python2-psycopg2
-	depends = python2-six
-	provides = python2-mbdata
-	conflicts = python2-mbdata
+pkgname = python-mbdata-git
 
diff --git a/PKGBUILD b/PKGBUILD
index 40c98c047f76..8ac014779494 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -3,58 +3,34 @@
 pkgbase=python-mbdata-git
 _pkgbase=${pkgbase%-git}
 _name=${_pkgbase#python-}
-pkgname=($pkgbase ${pkgbase/python-/python2-})
-pkgver=25.0.0.r0.g384f8ab
+pkgname=$pkgbase
+pkgver=25.0.4.r3.g5d8cadf
 pkgrel=1
 pkgdesc='MusicBrainz database tools for Python'
 url="https://github.com/lalinsky/$_name"
 arch=('any')
 license=('MIT')
-makedepends=('python-setuptools' 'python2-setuptools' 'git')
+depends=(python python-psycopg2 python-six)
+makedepends=('python-setuptools' 'git')
+provides=(${_pkgbase})
+conflicts=(${_pkgbase})
 source=("git+$url.git")
 sha256sums=('SKIP')
 
 pkgver() {
-  cd python3
+  cd "$_name"
   git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
 }
 
-prepare() {
-  cp -a $_name python2
-  mv $_name python3
-}
-
 build() {
-  pushd python3
+  cd "$_name"
   python3 setup.py build
-  popd
-
-  pushd python2
-  python2 setup.py build
 }
 
-package_python-mbdata-git() {
-  depends=(python python-psycopg2 python-six)
-  provides=(${_pkgbase})
-  conflicts=(${_pkgbase})
-
-  cd python3
+package() {
+  cd "$_name"
   python3 setup.py install --root="$pkgdir" --optimize=1 --skip-build
   install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$_pkgbase/LICENSE"
   install -d "$pkgdir/usr/share/doc/$_pkgbase"
   install -m644 -t "$pkgdir/usr/share/doc/$_pkgbase" README.rst CHANGELOG.rst settings.py.sample mbslave.conf.default
 }
-
-package_python2-mbdata-git() {
-  depends=(python2 python2-psycopg2 python2-six)
-  provides=(${_pkgbase/python-/python2-})
-  conflicts=(${_pkgbase/python-/python2-})
-
-  cd python2
-  python2 setup.py install --root="$pkgdir" --optimize=1 --skip-build
-  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/${_pkgbase/python-/python2-}/LICENSE"
-  install -d "$pkgdir/usr/share/doc/${_pkgbase/python-/python2-}"
-  install -m644 -t "$pkgdir/usr/share/doc/${_pkgbase/python-/python2-}" README.rst CHANGELOG.rst settings.py.sample mbslave.conf.default
-  # `mbslave` is provided by python-mbdata-git (for Python 3); no sense in duplicating
-  rm -rf "$pkgdir/usr/bin"
-}