Initial commit

2 files changed, 75 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..45858593d707
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,28 @@
+pkgbase = python-nmigen-git
+	pkgdesc = A refreshed Python toolbox for building complex digital hardware
+	pkgver = 0.2.r191.g2c505de
+	pkgrel = 1
+	url = https://github.com/nmigen/nmigen
+	arch = any
+	license = BSD
+	checkdepends = python-pytest
+	checkdepends = python-pyvcd
+	checkdepends = python-jinja
+	checkdepends = yosys-git
+	checkdepends = symbiyosys-git
+	checkdepends = yices
+	makedepends = git
+	makedepends = python-setuptools
+	makedepends = python-setuptools-scm
+	makedepends = python-pytest
+	depends = python
+	optdepends = python-pyvcd: for nmigen.pysim
+	optdepends = python-jinja: for nmigen.build
+	optdepends = paramiko: for remote builds
+	provides = python-nmigen=0.2.r191.g2c505de
+	conflicts = python-nmigen
+	source = git+https://github.com/nmigen/nmigen.git
+	sha256sums = SKIP
+
+pkgname = python-nmigen-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..85ec09e352fd
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
+
+_pkgname=nmigen
+pkgname="python-$_pkgname-git"
+pkgver=0.2.r191.g2c505de
+pkgrel=1
+pkgdesc="A refreshed Python toolbox for building complex digital hardware"
+arch=(any)
+url="https://github.com/nmigen/nmigen"
+license=('BSD')
+depends=('python')
+makedepends=('git' 'python-setuptools' 'python-setuptools-scm' 'python-pytest')
+optdepends=('python-pyvcd: for nmigen.pysim'
+            'python-jinja: for nmigen.build'
+            'paramiko: for remote builds')
+# FIXME: yosys>=0.9+3468, symbiyosys
+checkdepends=('python-pytest' 'python-pyvcd' 'python-jinja' 'yosys-git' 'symbiyosys-git' 'yices')
+provides=("python-nmigen=$pkgver")
+conflicts=('python-nmigen')
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+
+	git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd "$_pkgname"
+
+	python setup.py build
+}
+
+check() {
+	cd "$_pkgname"
+
+	PYTHONPATH=. pytest
+}
+
+package() {
+	cd "$_pkgname"
+
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	install -Dm 644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}