Include PR8691; use PEP517 build.

Pull request #8691 is for NumPy 1.24 support. Since python-numpy now
packages 1.24, merge it locally before building to provide initial
support.

2 files changed, 40 insertions, 11 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 81f46e193f9b..222e09af8559 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,16 +1,28 @@
 pkgbase = python-numba-git
 	pkgdesc = NumPy aware dynamic Python compiler using LLVM (Git version)
-	pkgver = 0.55.0dev0.r1004.g8f3cd87a0
+	pkgver = 0.57.0dev0.r1070.gfcdb0ee49.pr8691
 	pkgrel = 1
 	url = https://github.com/numba/numba
 	arch = x86_64
 	license = BSD
 	makedepends = git
-	depends = python-llvmlite>0.37.999
+	makedepends = openmp
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-wheel
+	makedepends = tbb
+	depends = python-llvmlite>0.39.999
 	depends = python-numpy
 	depends = python-setuptools
-	depends = tbb
-	provides = python-numba=0.55.0dev0.r1004.g8f3cd87a0
+	optdepends = openmp: OpenMP threading backend
+	optdepends = tbb: TBB threading backend
+	optdepends = python-scipy: cython bindings used in np.linalg.* support
+	optdepends = python-jinja: “pretty” type annotation output (HTML) via the CLI
+	optdepends = python-cffi: use of CFFI bindings in compiled functions
+	optdepends = python-yaml: use of a .numba_config.yaml file for storing per project configuration options
+	optdepends = python-colorama: error message highlighting
+	optdepends = python-pygments: “pretty” type annotation
+	provides = python-numba=0.57.0dev0.r1070.gfcdb0ee49.pr8691
 	conflicts = python-numba
 	source = git+https://github.com/numba/numba.git
 	sha256sums = SKIP
diff --git a/PKGBUILD b/PKGBUILD
index b2a236d86e69..64f2602eeb4c 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -3,33 +3,50 @@
 # Contributor: Michael Schubert <mschu.dev at gmail>
 
 pkgname=python-numba-git
-pkgver=0.55.0dev0.r1004.g8f3cd87a0
+pkgver=0.57.0dev0.r1070.gfcdb0ee49.pr8691
 pkgrel=1
 pkgdesc='NumPy aware dynamic Python compiler using LLVM (Git version)'
 url='https://github.com/numba/numba'
 arch=('x86_64')
 license=('BSD')
-depends=('python-llvmlite>0.37.999' 'python-numpy' 'python-setuptools' 'tbb')
-makedepends=('git')
+depends=('python-llvmlite>0.39.999' 'python-numpy' 'python-setuptools')
+optdepends=(
+  'openmp: OpenMP threading backend'
+  'tbb: TBB threading backend'
+  'python-scipy: cython bindings used in np.linalg.* support'
+  'python-jinja: “pretty” type annotation output (HTML) via the CLI'
+  'python-cffi: use of CFFI bindings in compiled functions'
+  'python-yaml: use of a .numba_config.yaml file for storing per project configuration options'
+  'python-colorama: error message highlighting'
+  'python-pygments: “pretty” type annotation'
+)
+makedepends=('git' 'openmp' 'python-build' 'python-installer' 'python-wheel' 'tbb')
 conflicts=('python-numba')
-replaces=()
 provides=("python-numba=$pkgver")
 source=('git+https://github.com/numba/numba.git')
 sha256sums=('SKIP')
 
+prepare() {
+  cd numba
+  git config --local user.name "makepkg"
+  git config --local user.email "makepkg@localhost"
+  git fetch origin refs/pull/8691/head:pr8691
+  git merge --commit --no-edit pr8691
+}
+
 pkgver() {
   cd numba
-  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+  printf "%s.pr8691" "$(git describe --long origin/HEAD | sed 's/\([^-]*-g\)/r\1/;s/-/./g')"
 }
 
 build() {
   cd numba
-  python setup.py build
+  python -m build --no-isolation --wheel
 }
 
 package() {
   cd numba
-  python setup.py install --skip-build --prefix=/usr --root="$pkgdir" --optimize=1
+  python -m installer --destdir="$pkgdir" dist/*.whl
   install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
   install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE LICENSES.third-party
 }