initial commit

3 files changed, 64 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..138ce356382a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = python-posthog
+	pkgdesc = Integrate PostHog into any python application.
+	pkgver = 3.3.2
+	pkgrel = 1
+	url = https://posthog.com/docs/libraries/python
+	arch = any
+	license = MIT
+	checkdepends = python-freezegun
+	checkdepends = python-mock
+	checkdepends = python-pytest
+	checkdepends = python-pytest-timeout
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-setuptools
+	makedepends = python-wheel
+	depends = python-backoff
+	depends = python-dateutil
+	depends = python-monotonic
+	depends = python-requests
+	depends = python-six
+	source = posthog-python-3.3.2.tar.gz::https://github.com/PostHog/posthog-python/archive/refs/tags/v3.3.2.tar.gz
+	sha256sums = 57fa0a6e0f5f29d3ac290680773958fc5fb09cb1c2ac7ee289d571c41660afbe
+
+pkgname = python-posthog
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..4dab8d6386e3
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,7 @@
+# Ignore everything
+*
+
+# But not these files...
+!.gitignore
+!PKGBUILD
+!.SRCINFO
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4282f3a5fa5d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,33 @@
+# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
+pkgname=python-posthog
+_name=posthog-python
+pkgver=3.3.2
+pkgrel=1
+pkgdesc="Integrate PostHog into any python application."
+arch=('any')
+url="https://posthog.com/docs/libraries/python"
+license=('MIT')
+depends=('python-backoff' 'python-dateutil' 'python-monotonic' 'python-requests' 'python-six')
+makedepends=('python-build' 'python-installer' 'python-setuptools' 'python-wheel')
+checkdepends=('python-freezegun' 'python-mock' 'python-pytest' 'python-pytest-timeout')
+source=("$_name-$pkgver.tar.gz::https://github.com/PostHog/posthog-python/archive/refs/tags/v$pkgver.tar.gz")
+sha256sums=('57fa0a6e0f5f29d3ac290680773958fc5fb09cb1c2ac7ee289d571c41660afbe')
+
+build() {
+  cd "$_name-$pkgver"
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd "$_name-$pkgver"
+
+  # Disable tests requiring network access
+  pytest -k 'not test_request'
+}
+
+package() {
+  cd "$_name-$pkgver"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}