package overhaul

2 files changed, 24 insertions, 45 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 5fdbd970d392..7640af1eaa33 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,18 +1,19 @@
 pkgbase = python-pymarc-git
-	pkgdesc = A Python 3 library for working with bibliographic data encoded in MARC21
-	pkgver = 3.0.3.r283.9e77090
-	pkgrel = 2
-	url = https://github.com/edsu/pymarc
+	pkgdesc = Python library for working with bibliographic data encoded in MARC21
+	pkgver = 4.1.3.r2.g953c5c3
+	pkgrel = 1
+	url = https://gitlab.com/pymarc/pymarc
 	arch = any
 	license = BSD
 	makedepends = git
+	makedepends = python-build
+	makedepends = python-installer
 	makedepends = python-setuptools
+	makedepends = python-wheel
 	depends = python
-	depends = python-six
 	provides = python-pymarc
 	conflicts = python-pymarc
-	source = git+https://github.com/edsu/pymarc.git
+	source = pymarc::git+https://gitlab.com/pymarc/pymarc
 	sha256sums = SKIP
 
 pkgname = python-pymarc-git
-
diff --git a/PKGBUILD b/PKGBUILD
index 2d1eec860957..e2d75008b87e 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -1,42 +1,27 @@
-# Maintainer:  jyantis <yantis@yantis.net>
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor:  jyantis <yantis@yantis.net>
 
 pkgname=python-pymarc-git
-pkgver=3.0.3.r283.9e77090
-pkgrel=2
-pkgdesc='A Python 3 library for working with bibliographic data encoded in MARC21'
+pkgver=4.1.3.r2.g953c5c3
+pkgrel=1
+pkgdesc='Python library for working with bibliographic data encoded in MARC21'
 arch=('any')
-url='https://github.com/edsu/pymarc'
+url='https://gitlab.com/pymarc/pymarc'
 license=('BSD')
-depends=('python' 'python-six')
-source=('git+https://github.com/edsu/pymarc.git')
-sha256sums=('SKIP')
-makedepends=('git' 'python-setuptools')
+depends=('python')
+makedepends=('git' 'python-build' 'python-installer' 'python-setuptools' 'python-wheel')
 provides=('python-pymarc')
 conflicts=('python-pymarc')
+source=("pymarc::git+$url")
+sha256sums=('SKIP')
 
 pkgver() {
-  cd pymarc
-  set -o pipefail
-  _gitversion=$( git describe --long | sed -r 's/([^-]*-g)/r\1/;s/-/./g' ||
-  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)" )
-
-  # If there is a setup.py then pull the version tag from the file
-  if [ -f "setup.py" ]; then
-    if grep --quiet "version = " setup.py; then
-      printf "%s.%s" "$(grep -R "version = " setup.py | awk -F\' '{print $2}')" $_gitversion | sed 's/-/./g'
-    elif grep --quiet "version=" setup.py; then
-      printf "%s.%s" "$(grep -R "version=" setup.py | awk -F\' '{print $2}')" $_gitversion | sed 's/-/./g'
-    else
-      printf "%s" $_gitversion
-    fi
-  else
-    printf "%s" $_gitversion
-  fi
+  git -C pymarc describe --long --tags | sed 's/^v//;s/-/.r/;s/-/./'
 }
 
 build() {
   cd pymarc
-  python setup.py build
+  python -m build --wheel --no-isolation
 }
 
 check() {
@@ -46,17 +31,10 @@ check() {
 
 package() {
   cd pymarc
-
-  # We don't need anything related to git in the package
-  rm -rf .git*
-
-  python setup.py install --root="${pkgdir}" --optimize=1
-
-  # Install License
-  install -D -m644 README.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-
-  # Install Documentation
-  install -D -m644 README.md "${pkgdir}/usr/share/doc/${pkgname}/README.md"
+  PYTHONHASHSEED=0 python -m installer --destdir="$pkgdir" dist/*.whl
+  local _site="$(python -c 'import site; print(site.getsitepackages()[0])')"
+  install -d "$pkgdir/usr/share/licenses/$pkgname/"
+  ln -s "$_site/pymarc-${pkgver%.r*}.dist-info/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/"
 }
 
 # vim:set ts=2 sw=2 et: