Initial commit

2 files changed, 64 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..363b3db774c3
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = python-pysat-git
+	pkgdesc = A toolkit for SAT-based prototyping in Python
+	pkgver = 0.1.6.dev6.r16.g58a7658
+	pkgrel = 1
+	url = https://github.com/pysathq/pysat
+	arch = x86_64
+	license = MIT
+	checkdepends = python-pytest
+	makedepends = git
+	makedepends = python-setuptools
+	depends = python
+	provides = python-pysat=0.1.6.dev6.r16.g58a7658
+	conflicts = python-pysat
+	source = git+https://github.com/pysathq/pysat.git
+	sha256sums = SKIP
+
+pkgname = python-pysat-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..af00550636b0
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
+
+_pkgname=pysat
+pkgname="python-$_pkgname-git"
+pkgver=0.1.6.dev6.r16.g58a7658
+pkgrel=1
+pkgdesc="A toolkit for SAT-based prototyping in Python"
+arch=(x86_64)
+url="https://github.com/pysathq/pysat"
+license=('MIT')
+depends=('python')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest')
+provides=("${pkgname%%-git}=$pkgver")
+conflicts=("${pkgname%%-git}")
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd "$_pkgname"
+
+	python setup.py build
+}
+
+check() {
+	cd "$_pkgname"
+
+	local python_version=$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')
+
+	touch tests/__init__.py
+	PYTHONPATH="$PWD/build/lib.linux-$CARCH-${python_version}" pytest
+}
+
+package() {
+	cd "$_pkgname"
+
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	install -Dm 644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}