Initial commit

2 files changed, 62 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..18f1c7701f9b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = python-sdf-timing-git
+	pkgdesc = Python library for working Standard Delay Format (SDF) Timing Annotation files
+	pkgver = r104.5740ac4
+	pkgrel = 1
+	url = https://github.com/SymbiFlow/python-sdf-timing
+	arch = any
+	license = ISC
+	checkdepends = python-pytest
+	makedepends = git
+	makedepends = python-setuptools
+	depends = python
+	depends = python-ply
+	provides = python-sdf-timing
+	conflicts = python-sdf-timing
+	source = git+https://github.com/SymbiFlow/python-sdf-timing.git
+	sha256sums = SKIP
+
+pkgname = python-sdf-timing-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b33648fc7465
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
+
+_pkgname=python-sdf-timing
+pkgname="$_pkgname-git"
+pkgver=r104.5740ac4
+pkgrel=1
+pkgdesc="Python library for working Standard Delay Format (SDF) Timing Annotation files"
+arch=(any)
+url="https://github.com/SymbiFlow/python-sdf-timing"
+license=('ISC')
+depends=('python' 'python-ply')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest')
+provides=("${pkgname%%-git}")
+conflicts=("${pkgname%%-git}")
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+
+build() {
+	cd "$_pkgname"
+
+	python setup.py build
+}
+
+check() {
+	cd "$_pkgname"
+
+	PYTHONPATH=. pytest
+}
+
+package() {
+	cd "$_pkgname"
+
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}