New source for python-tabulate from git

2 files changed, 63 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..c7ca8472e221
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,20 @@
+pkgbase = python-tabulate-git
+	pkgdesc = Pretty-print tabular data in Python, a library and a command-line utility.
+	pkgver = 0.8.3.r361.159c1fb
+	pkgrel = 1
+	url = https://bitbucket.org/astanin/python-tabulate
+	arch = any
+	license = MIT
+	makedepends = python-setuptools
+	makedepends = python2-setuptools
+	source = tabulate::git+https://bitbucket.org/astanin/python-tabulate.git
+	sha1sums = SKIP
+
+pkgname = python-tabulate-git
+	provides = python-tabulate
+	conflicts = python-tabulate
+
+pkgname = python2-tabulate-git
+	provides = python2-tabulate
+	conflicts = python2-tabulate
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..cb94a72d26c9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Sergey Astanin s<dot>astanin<at>gmail<dot>com
+# Contributor: Mikhail felixoid Shiryaev mr<dot>felixoid<at>gmail<dot>com
+
+_name=tabulate
+pkgdesc='Pretty-print tabular data in Python, a library and a command-line utility.'
+url="https://bitbucket.org/astanin/python-tabulate"
+pkgbase="python-${_name}-git"
+pkgname=("python-${_name}-git" "python2-${_name}-git")
+pkgver=0.8.3.r361.159c1fb
+pkgrel=1
+arch=('any')
+makedepends=('python-setuptools' 'python2-setuptools')
+license=('MIT')
+source=("${_name}::git+${url}.git")
+sha1sums=('SKIP')
+
+pkgver() {
+	cd "${_name}"
+	_version=$(python setup.py -V)
+	( set -o pipefail
+		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+		printf "%s.r%s.%s" "${_version}" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+package_python2-tabulate-git() {
+	provides=( 'python2-tabulate' )
+	conflicts=( 'python2-tabulate' )
+	cd "${srcdir}/${_name}"
+	python2 setup.py install --root="${pkgdir}" --optimize=1
+	# Waiting for https://github.com/axiros/terminal_markdown_viewer/pull/42
+	mv "${pkgdir}/usr/bin/${_name}"  "${pkgdir}/usr/bin/${_name}2"
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/"LICENSE
+}
+
+package_python-tabulate-git() {
+	provides=( 'python-tabulate' )
+	conflicts=( 'python-tabulate' )
+	cd "${srcdir}/${_name}"
+	python setup.py install --root="${pkgdir}" --optimize=1
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/"LICENSE
+}
+