initial commit

2 files changed, 79 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..389798c0c73f
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,24 @@
+pkgbase = python-tcod
+	pkgdesc = High-performance Python port of libtcod
+	pkgver = 13.0.0
+	pkgrel = 1
+	url = https://github.com/libtcod/python-tcod
+	arch = x86_64
+	license = BSD
+	makedepends = git
+	makedepends = python-setuptools
+	makedepends = python-pytest-runner
+	makedepends = python-pycparser>=2.14
+	makedepends = python-sphinx
+	makedepends = sdl2>=2.0.5
+	depends = libtcod
+	depends = python-cffi
+	depends = python-numpy>=1.20.3
+	depends = python-typing_extensions
+	source = python-tcod-13.0.0::git+https://github.com/libtcod/python-tcod#tag=13.0.0?signed
+	source = libtcod::git+https://github.com/libtcod/libtcod#tag=1.18.1?signed
+	validpgpkeys = 9EF1E80F3817BC043097A7C15814977902B194CC
+	sha256sums = SKIP
+	sha256sums = SKIP
+
+pkgname = python-tcod
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..475256e7c2c3
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,55 @@
+# Maintainer: Luis Martinez <luis dot martinez at disroot dot org>
+# Contributor: Maximilian Stahlberg <maximilian.stahlberg tu-berlin de>
+# Contributor: Feufochmar <feufochmar dot gd at gmail dot com>
+
+pkgname=python-tcod
+pkgver=13.0.0
+pkgrel=1
+pkgdesc='High-performance Python port of libtcod'
+arch=('x86_64')
+url='https://github.com/libtcod/python-tcod'
+license=('BSD')
+depends=(
+	'libtcod'
+	'python-cffi'
+	'python-numpy>=1.20.3'
+	'python-typing_extensions')
+makedepends=(
+	'git'
+	'python-setuptools'
+	'python-pytest-runner'
+	'python-pycparser>=2.14'
+	'python-sphinx'
+	'sdl2>=2.0.5')
+source=("$pkgname-$pkgver::git+$url#tag=$pkgver?signed"
+        'libtcod::git+https://github.com/libtcod/libtcod#tag=1.18.1?signed')
+sha256sums=('SKIP'
+            'SKIP')
+validpgpkeys=('9EF1E80F3817BC043097A7C15814977902B194CC') # Kyle Benesch @ GitHub
+
+prepare() {
+	cd "$pkgname-$pkgver"
+	git submodule init
+	git config submodule.libtcod.url "$srcdir/libtcod"
+	git submodule update
+}
+
+build() {
+	cd "$pkgname-$pkgver"
+	python setup.py build
+	cd docs
+	make man
+}
+
+# check() {
+# 	cd "$pkgname-$pkgver"
+# 	local _ver="$(python -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"
+# 	PYTHONPATH="$PWD/build/lib.linux-$CARCH-$_ver" python setup.py pytest
+# }
+
+package() {
+	cd "$pkgname-$pkgver"
+	PYTHONHASHSEED=0 python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
+	install -Dm 644 LICENSE.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
+	install -Dm 644 docs/_build/man/python-tcod.1 -t "$pkgdir/usr/share/man/man1/"
+}