Moved upstream to forked repo and added some other meta data

- Moved to forked repo https://github.com/matthewdeanmartin/terminaltables
- Updated PKGBUILD to conform to Python packaging guidelines https://wiki.archlinux.org/title/Python_package_guidelines#Standards_based_(PEP_517)
- Added conflict with python-terminaltables
- Implemented git tag based pkgver()

2 files changed, 21 insertions, 18 deletions

diff --git a/.SRCINFO b/.SRCINFO
index 7017b0d9325c..9751def0065e 100644
--- a/.SRCINFO
+++ b/.SRCINFO
@@ -1,17 +1,15 @@
-# Generated by mksrcinfo v8
-# Tue Feb 14 22:07:19 UTC 2017
 pkgbase = python-terminaltables-git
 	pkgdesc = Generate simple tables in terminals from a nested list of strings.
-	pkgver = r131.ae22aaa
+	pkgver = v3.1.9.r3.g8020b8c
 	pkgrel = 1
-	url = https://github.com/Robpol86/terminaltables
+	url = https://github.com/matthewdeanmartin/terminaltables
 	arch = any
 	license = MIT
 	makedepends = git
 	makedepends = python-setuptools
 	provides = python-terminaltables
-	source = git+https://github.com/Robpol86/terminaltables.git
+	conflicts = python-terminaltables
+	source = git+https://github.com/matthewdeanmartin/terminaltables.git
 	sha256sums = SKIP
 
 pkgname = python-terminaltables-git
-
diff --git a/PKGBUILD b/PKGBUILD
index 83e5fdb61ddf..214effd35223 100644
--- a/PKGBUILD
+++ b/PKGBUILD
@@ -2,27 +2,32 @@
 
 _gitname=terminaltables
 pkgname=python-terminaltables-git
-pkgver='r131.ae22aaa'
+pkgver=v3.1.9.r3.g8020b8c
 pkgrel=1
 arch=('any')
 pkgdesc='Generate simple tables in terminals from a nested list of strings.'
 license=('MIT')
 makedepends=('git' 'python-setuptools')
 provides=('python-terminaltables')
-url='https://github.com/Robpol86/terminaltables'
-source=("git+https://github.com/Robpol86/terminaltables.git")
+conflicts=('python-terminaltables')
+url='https://github.com/matthewdeanmartin/terminaltables'
+source=("git+https://github.com/matthewdeanmartin/terminaltables.git")
 sha256sums=('SKIP')
 
-package() {
+pkgver() {
   cd "${_gitname}"
+  git describe --long --abbrev=7 --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
 
-  # We don't need anything related to git in the package
-  rm -rf .git*
-
-  # Install
-  python setup.py install --optimize=1 --root="${pkgdir}"
+build() {
+  cd ${_gitname}
+  python -m build --wheel --no-isolation
+}
 
-  # Install License
-  # MIT/X11 license
-  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+package() {
+  cd ${_gitname}
+  python -m installer --destdir="$pkgdir" --compile-bytecode=2 dist/*.whl
+  install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 example*.py -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
 }