Initial commit

2 files changed, 63 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..5334ba44453d
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = python-vtr-xml-utils-git
+	pkgdesc = Utilities for working with VtR XML Files
+	pkgver = r86.d6ba1f1
+	pkgrel = 1
+	url = https://github.com/SymbiFlow/vtr-xml-utils
+	arch = any
+	license = ISC
+	checkdepends = python-pytest
+	makedepends = git
+	makedepends = python-setuptools
+	depends = python
+	depends = python-lxml
+	provides = python-vtr-xml-utils
+	conflicts = python-vtr-xml-utils
+	source = git+https://github.com/SymbiFlow/vtr-xml-utils.git
+	sha256sums = SKIP
+
+pkgname = python-vtr-xml-utils-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..1d60a83a53a6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
+
+_pkgname=vtr-xml-utils
+pkgname="python-$_pkgname-git"
+pkgver=r86.d6ba1f1
+pkgrel=1
+pkgdesc="Utilities for working with VtR XML Files"
+arch=(any)
+url="https://github.com/SymbiFlow/vtr-xml-utils"
+license=('ISC')
+depends=('python' 'python-lxml')
+makedepends=('git' 'python-setuptools')
+checkdepends=('python-pytest')
+provides=("${pkgname%%-git}")
+conflicts=("${pkgname%%-git}")
+source=("git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "$_pkgname"
+
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	cd "$_pkgname"
+
+	python setup.py build
+}
+
+check() {
+	cd "$_pkgname"
+
+	touch tests/__init__.py
+	pytest
+}
+
+package() {
+	cd "$_pkgname"
+
+	python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+
+	install -Dm 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}