Initial commit

2 files changed, 53 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..4b0c754522f2
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = qmasterpassword
+	pkgdesc = stateless Master Password Manager
+	pkgver = 1.2.2
+	pkgrel = 1
+	url = https://github.com/bkueng/qMasterPassword
+	arch = x86_64
+	license = GPL
+	depends = qt5-base
+	depends = libscrypt-git
+	depends = libxtst
+	source = https://github.com/bkueng/qMasterPassword/archive/v1.2.2.tar.gz
+	md5sums = 3ff8f256a81c30518bce959ea88f3c3d
+
+pkgname = qmasterpassword
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..e6d07a6ae966
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Morgana <morganamilo@gmail.com>
+pkgname=qmasterpassword
+_pkgname=qMasterPassword
+pkgver=1.2.2
+pkgrel=1
+pkgdesc="stateless Master Password Manager"
+arch=(x86_64)
+url="https://github.com/bkueng/qMasterPassword"
+license=('GPL')
+depends=("qt5-base" "libscrypt-git" "libxtst") #non git version does not build
+source=("https://github.com/bkueng/qMasterPassword/archive/v1.2.2.tar.gz")
+md5sums=('3ff8f256a81c30518bce959ea88f3c3d')
+
+prepare() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	sed -i "s/Exec=${_pkgname}/Exec=${pkgname}/g" "data/${_pkgname}.desktop"
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+	qmake
+	make
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}-${pkgver}"
+
+	install -Dm755 "${_pkgname}" "${pkgdir}/usr/bin/${pkgname}"
+	install -Dm644 "data/${_pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
+
+	install -d "${pkgdir}/usr/share/icons"
+	cp -a "data/icons" "${pkgdir}/usr/share/icons/${pkgname}"
+
+	install -Dm644 "data/icons/app_icon.png" "${pkgdir}/usr/share/icons/hicolor/512x512/apps/${pkgname}.png"
+
+	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
+	install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
+}