5.9.99-1

3 files changed, 90 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..82bee4ff2176
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,26 @@
+pkgbase = radium-bin
+	pkgdesc = A graphical music editor. A next generation tracker. (Demo Version)
+	pkgver = 5.9.99
+	pkgrel = 1
+	url = https://users.notam02.no/~kjetism/radium
+	arch = x86_64
+	groups = pro-audio
+	license = GPL2
+	depends = desktop-file-utils
+	depends = glu
+	depends = hicolor-icon-theme
+	depends = jack2
+	depends = libsm
+	depends = libxcomposite
+	depends = libxrender
+	depends = shared-mime-info
+	depends = ttf-bitstream-vera
+	optdepends = new-session-manager: for session management
+	provides = radium
+	conflicts = radium
+	options = !strip
+	source = https://users.notam02.no/~kjetism/radium/demos/linux/radium_64bit_linux-5.9.99-demo.tar.xz
+	sha256sums = 4c262986eb4ca57385be25a6c362bc3737890660734032a9cf7e4d9fc7ffb9cf
+
+pkgname = radium-bin
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..aabc5d3e2544
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,4 @@
+*.tar.*
+*.log
+pkg/
+src/
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..5ba4d19355a9
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,60 @@
+# Maintainer: Teteros <teteros at teknik dot io>
+
+pkgname=radium-bin
+pkgver=5.9.99
+pkgrel=1
+pkgdesc='A graphical music editor. A next generation tracker. (Demo Version)'
+arch=(x86_64)
+url="https://users.notam02.no/~kjetism/radium"
+license=(GPL2)
+provides=(radium)
+conflicts=(radium)
+groups=(pro-audio)
+depends=(
+  desktop-file-utils
+  glu
+  hicolor-icon-theme
+  jack2
+  libsm
+  libxcomposite
+  libxrender
+  shared-mime-info
+  ttf-bitstream-vera
+)
+optdepends=('new-session-manager: for session management')
+options=(!strip)
+source=("https://users.notam02.no/~kjetism/radium/demos/linux/radium_64bit_linux-$pkgver-demo.tar.xz")
+sha256sums=('4c262986eb4ca57385be25a6c362bc3737890660734032a9cf7e4d9fc7ffb9cf')
+
+package() {
+  # Copy radium files to a self-contained /opt prefix
+  mkdir -p "$pkgdir/opt/radium"
+  cp -a radium_64bit_linux-$pkgver-demo/bin "$pkgdir/opt/radium"
+  cp -a radium_64bit_linux-$pkgver-demo/lib "$pkgdir/opt/radium/"
+
+  # Nouveau and AMD drivers require a newer libstdc++ than Radium provides so removing it is necessary to not crash
+  rm "$pkgdir/opt/radium/lib/libstdc++.so.6"
+
+  # Generate a dummy libselinux.so because official builds link to it for some reason
+  echo "extern int is_selinux_enabled(void){return 0;}" > selinux-dummy.c
+  gcc -s -shared -o "$pkgdir/opt/radium/lib/libselinux.so.1" selinux-dummy.c
+  rm selinux-dummy.c
+
+  # Create startup script similar to run_radium.sh
+  mkdir -p "$pkgdir/usr/bin"
+  echo '#!/usr/bin/env bash' > "$pkgdir/usr/bin/radium"
+  echo LD_LIBRARY_PATH='"/opt/radium/lib:$LD_LIBRARY_PATH"' QT_QPA_PLATFORM_PLUGIN_PATH=/opt/radium/bin/qt5_plugins \
+    /opt/radium/bin/radium '"$@"' >> "$pkgdir/usr/bin/radium"
+  chmod +x "$pkgdir/usr/bin/radium"
+
+  # Icons, .desktop and mimetype files
+  mkdir -p "$pkgdir/usr/share/icons/hicolor/"{16x16,32x32,128x128,256x256}"/apps" \
+    "$pkgdir/usr/share/applications" \
+    "$pkgdir/usr/share/mime/packages"
+  ln -s "/opt/radium/bin/radium_16x16x8.png" "$pkgdir/usr/share/icons/hicolor/16x16/apps/radium.png"
+  ln -s "/opt/radium/bin/radium_32x32x24.png" "$pkgdir/usr/share/icons/hicolor/32x32/apps/radium.png"
+  ln -s "/opt/radium/bin/radium_128x128x32.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/radium.png"
+  ln -s "/opt/radium/bin/radium_256x256x32.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/radium.png"
+  ln -s "/opt/radium/bin/radium.desktop" "$pkgdir/usr/share/applications/radium.desktop"
+  ln -s "/opt/radium/bin/radium-mimetype.xml" "$pkgdir/usr/share/mime/packages/radium.xml"
+}