initial commit

3 files changed, 65 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..be8444a7f6d3
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = resvg-git
+	pkgdesc = SVG rendering library and CLI
+	pkgver = 0.4.0.r6.g9891e06
+	pkgrel = 1
+	url = https://github.com/RazrFalcon/resvg
+	arch = i686
+	arch = x86_64
+	license = MPL2
+	makedepends = cargo
+	makedepends = qt5-base
+	makedepends = pango
+	provides = resvg
+	conflicts = resvg
+	source = git+https://github.com/RazrFalcon/resvg.git#branch=master
+	sha256sums = SKIP
+
+pkgname = resvg-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..c47d1d61a18a
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,5 @@
+/src/
+/pkg/
+/*.tar.gz
+/*.pkg.*
+resvg/
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..4a9be688a849
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,42 @@
+_pkgname=resvg
+pkgname=${_pkgname}-git
+pkgver=0.4.0.r6.g9891e06
+pkgrel=1
+pkgdesc='SVG rendering library and CLI'
+arch=(i686 x86_64)
+url="https://github.com/RazrFalcon/$_pkgname"
+license=(MPL2)
+makedepends=(cargo qt5-base pango)
+conflicts=(resvg)
+provides=(resvg)
+source=("git+${url}.git#branch=master")
+sha256sums=('SKIP')
+
+pkgver() {
+	cd "${srcdir}/${_pkgname}"
+	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
+}
+
+build() {
+	cd "${srcdir}/${_pkgname}"
+	for dir in capi tools/rendersvg; do
+	(
+		msg2 "Building $dir"
+		cd "$dir"
+		cargo build --release --features='qt-backend cairo-backend'
+	)
+	done
+	
+	msg2 'Building docs'
+	cargo doc --release
+}
+
+package() {
+	cd "${srcdir}/${_pkgname}"
+	
+	install -Dm755 target/release/rendersvg   "$pkgdir/usr/bin/rendersvg"
+	install -Dm755 target/release/libresvg.so "$pkgdir/usr/lib/libresvg.so"
+	install -Dm644 capi/include/resvg.h       "$pkgdir/usr/include/resvg.h"
+	install -d "$pkgdir/usr/share/doc/resvg"
+	cp -r target/doc/* "$pkgdir/usr/share/doc/resvg"
+}