update to r189.07ed4b0

2 files changed, 86 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a0d4a034f5f8
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,32 @@
+pkgbase = rpcsx-git
+	pkgdesc = Sony PlayStation 4 emulator
+	pkgver = r189.07ed4b0
+	pkgrel = 1
+	url = https://rpcsx.github.io/rpcsx-site/
+	arch = x86_64
+	license = GPL2
+	license = MIT
+	makedepends = cmake
+	makedepends = git
+	makedepends = glslang
+	makedepends = spirv-cross
+	makedepends = vulkan-headers>=1:1.3
+	makedepends = vulkan-icd-loader>=1.3
+	makedepends = xbyak
+	depends = gcc-libs
+	depends = glfw>=3.3
+	depends = glibc
+	depends = libunwind
+	depends = spirv-tools
+	provides = rpcsx=189.07ed4b0
+	conflicts = rpcsx
+	source = rpcsx::git+https://github.com/RPCSX/rpcsx.git
+	b2sums = SKIP
+
+pkgname = rpcsx-git
+	depends = gcc-libs
+	depends = glfw>=3.3
+	depends = glibc
+	depends = libunwind
+	depends = spirv-tools
+	depends = libvulkan.so
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..098916ce00d2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,54 @@
+# Maintainer: Alexandre Bouvier <contact@amb.tf>
+_pkgname=rpcsx
+pkgname=$_pkgname-git
+pkgver=r189.07ed4b0
+pkgrel=1
+pkgdesc="Sony PlayStation 4 emulator"
+arch=('x86_64')
+url="https://rpcsx.github.io/rpcsx-site/"
+license=('GPL2' 'MIT')
+depends=(
+	'gcc-libs'
+	'glfw>=3.3'
+	'glibc'
+	'libunwind'
+	'spirv-tools'
+)
+makedepends=(
+	'cmake'
+	'git'
+	'glslang'
+	'spirv-cross'
+	'vulkan-headers>=1:1.3'
+	'vulkan-icd-loader>=1.3'
+	'xbyak'
+)
+provides=("$_pkgname=${pkgver#r}")
+conflicts=("$_pkgname")
+source=("$_pkgname::git+https://github.com/RPCSX/rpcsx.git")
+b2sums=('SKIP')
+
+pkgver() {
+	cd $_pkgname
+	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+	sed -i 's/-march=native//' $_pkgname/rpcsx-os/CMakeLists.txt
+}
+
+build() {
+	cmake -S $_pkgname -B build \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_CXX_FLAGS_RELEASE="-DNDEBUG" \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-Wno-dev
+	cmake --build build
+}
+
+package() {
+	depends+=('libvulkan.so')
+	# shellcheck disable=SC2154
+	DESTDIR="$pkgdir" cmake --install build
+	install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname $_pkgname/orbis-kernel/LICENSE
+}