initial commit

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7a860f8cf1d6
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,15 @@
+pkgbase = rss-email-git
+	pkgdesc = Send new RSS posts as E-Mail
+	pkgver = 0.3.0.r0.ga0b828d
+	pkgrel = 1
+	url = https://sr.ht/~witcher/rss-email
+	arch = x86_64
+	license = WTFPL
+	makedepends = rust
+	makedepends = scdoc
+	depends = sqlite
+	conflicts = rss-email
+	source = rss-email-git::git+https://git.sr.ht/~witcher/rss-email
+	sha256sums = SKIP
+
+pkgname = rss-email-git
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bbfd4fe00543
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: witcher <witcher@wiredspace.de>
+
+_name="rss-email"
+pkgname="${_name}-git"
+pkgver=0.3.0.r0.ga0b828d
+pkgrel=1
+pkgdesc="Send new RSS posts as E-Mail"
+arch=('x86_64')
+url="https://sr.ht/~witcher/${_name}"
+license=('WTFPL')
+conflicts=('rss-email')
+depends=('sqlite')
+makedepends=('rust' 'scdoc')
+source=("$pkgname::git+https://git.sr.ht/~witcher/${_name}")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+	cd "$pkgname"
+
+	export CARGO_TARGET_DIR="target"
+	cargo build --release --locked
+
+	scdoc < "docs/${_name}.1.scd" | gzip > "docs/${_name}.1.gz"
+}
+
+package() {
+	cd "$pkgname"
+
+	install -Dm755 "target/release/${_name}" "${pkgdir}/usr/bin/${_name}"
+	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${_name}/LICENSE"
+	install -Dm644 "docs/${_name}.1.gz" "${pkgdir}/usr/share/man/man1/${_name}.1.gz"
+}