Initial upload: rusolver-git 0.2.0.r0.gc6ec585-1

2 files changed, 55 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..3a5c391f7512
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = rusolver-git
+	pkgdesc = Fast and accurate DNS resolver (git)
+	pkgver = 0.2.0.r0.gc6ec585
+	pkgrel = 1
+	url = https://github.com/Edu4rdSHL/rusolver
+	arch = x86_64
+	license = GPL3
+	makedepends = cargo
+	makedepends = git
+	provides = rusolver
+	conflicts = rusolver
+	conflicts = rusolver-bin
+	source = git+https://github.com/Edu4rdSHL/rusolver
+	sha512sums = SKIP
+
+pkgname = rusolver-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..95ba06b1b13f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# Maintainer: Edu4rdSHL <edu4rdshl@securityhacklabs.net>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=rusolver-git
+pkgver=0.2.0.r0.gc6ec585
+pkgrel=1
+pkgdesc="Fast and accurate DNS resolver (git)"
+arch=('x86_64')
+url="https://github.com/Edu4rdSHL/rusolver"
+license=('GPL3')
+makedepends=('cargo' 'git')
+conflicts=("${pkgname%-git}" "${pkgname%-git}-bin")
+provides=("${pkgname%-git}")
+source=("git+${url}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --locked --all-features
+}
+
+check() {
+  cd "${pkgname%-git}"
+  cargo test --release --locked
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 "${pkgname%-git}.1" -t "$pkgdir/usr/share/man/man1"
+}