Initial upload: rusty-krab-manager-git 1.0.r11.g0e5f3d8-1

2 files changed, 49 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..0b0e8ba0e8fb
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = rusty-krab-manager-git
+	pkgdesc = Time management TUI (git)
+	pkgver = 1.0.r11.g0e5f3d8
+	pkgrel = 1
+	url = https://github.com/aryakaul/rusty-krab-manager
+	arch = x86_64
+	license = custom
+	makedepends = cargo
+	makedepends = git
+	makedepends = alsa-lib
+	provides = rusty-krab-manager
+	conflicts = rusty-krab-manager
+	source = git+https://github.com/aryakaul/rusty-krab-manager
+	sha512sums = SKIP
+
+pkgname = rusty-krab-manager-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f59c5e27f8aa
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,32 @@
+# Maintainer: orhun <orhunparmaksiz@gmail.com>
+# https://github.com/orhun/pkgbuilds
+
+pkgname=rusty-krab-manager-git
+pkgver=1.0.r11.g0e5f3d8
+pkgrel=1
+pkgdesc="Time management TUI (git)"
+arch=('x86_64')
+url="https://github.com/aryakaul/rusty-krab-manager"
+license=('custom')
+makedepends=('cargo' 'git' 'alsa-lib')
+conflicts=("${pkgname%-git}")
+provides=("${pkgname%-git}")
+source=("git+${url}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd "${pkgname%-git}"
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${pkgname%-git}"
+  cargo build --release --all-features
+}
+
+package() {
+  cd "${pkgname%-git}"
+  install -Dm 755 "target/release/${pkgname%-git}" -t "${pkgdir}/usr/bin"
+  install -Dm 644 README.md -t "$pkgdir/usr/share/doc/${pkgname%-git}"
+  install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/${pkgname%-git}"
+}