Initial commit

3 files changed, 101 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a03177fd9c0a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = saber
+	pkgdesc = A cross-platform libre notes app written in Flutter
+	pkgver = 0.12.9
+	pkgrel = 1
+	url = https://github.com/adil192/saber
+	arch = x86_64
+	license = GPL3
+	makedepends = flutter
+	makedepends = clang
+	makedepends = cmake
+	makedepends = ninja
+	makedepends = pkgconf
+	makedepends = xz
+	makedepends = rustup
+	depends = gtk3
+	source = https://github.com/adil192/saber/archive/refs/tags/v0.12.9.tar.gz
+	source = 0001-Modify-.desktop-for-Arch-Linux.patch
+	sha256sums = 3f1fbde854b30d9f60ab3a7ccf863662586f165fb6273dc0f2cfe9d13528b52f
+	sha256sums = 93e6e067fefad597117d7f6889df204082898b79dcd29853eaa5c879ab35b2df
+
+pkgname = saber
diff --git a/0001-Modify-.desktop-for-Arch-Linux.patch b/0001-Modify-.desktop-for-Arch-Linux.patch
new file mode 100644
index 000000000000..a0ddf216e724
--- /dev/null
+++ b/0001-Modify-.desktop-for-Arch-Linux.patch
@@ -0,0 +1,29 @@
+From 4ba43ff9f1f9b522ab4a124f04fe949e776a9999 Mon Sep 17 00:00:00 2001
+From: Polarian <polarian@polarian.dev>
+Date: Wed, 31 May 2023 21:19:50 +0100
+Subject: [PATCH] Modify .desktop for Arch Linux
+
+---
+ flatpak/com.adilhanney.saber.desktop => saber.desktop | 2 +-
+ 1 file changed, 1 insertion(+), 1 deletion(-)
+ rename flatpak/com.adilhanney.saber.desktop => saber.desktop (91%)
+
+diff --git a/flatpak/com.adilhanney.saber.desktop b/saber.desktop
+similarity index 91%
+rename from flatpak/com.adilhanney.saber.desktop
+rename to saber.desktop
+index c6c6fe4a..c7f8017d 100644
+--- a/flatpak/com.adilhanney.saber.desktop
++++ b/saber.desktop
+@@ -7,7 +7,7 @@ Comment=A cross-platform libre handwritten notes app.
+ Comment[cs]=Volně dostupná multiplatformní aplikace pro ručně psané poznámky
+ Categories=Office;WordProcessor;
+ 
+-Icon=com.adilhanney.saber
++Icon=saber
+ Exec=saber
+ Terminal=false
+ StartupWMClass=saber
+-- 
+2.40.1
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..f45ee947ff37
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: Polarian <polarian@polarian.dev>
+
+pkgname=saber
+pkgver=0.12.9
+pkgrel=1
+pkgdesc="A cross-platform libre notes app written in Flutter"
+arch=('x86_64')
+url="https://github.com/adil192/saber"
+license=('GPL3')
+depends=('gtk3')
+makedepends=('flutter' 'clang' 'cmake' 'ninja' 'pkgconf' 'xz' 'rustup')
+source=("https://github.com/adil192/$pkgname/archive/refs/tags/v$pkgver.tar.gz"
+        "0001-Modify-.desktop-for-Arch-Linux.patch")
+sha256sums=('3f1fbde854b30d9f60ab3a7ccf863662586f165fb6273dc0f2cfe9d13528b52f'
+            '93e6e067fefad597117d7f6889df204082898b79dcd29853eaa5c879ab35b2df')
+
+prepare() {
+    cd "$pkgname-$pkgver"
+
+    # Patch source to allow for better .desktop naming
+    patch -p1 -i "$srcdir/0001-Modify-.desktop-for-Arch-Linux.patch"
+
+    # Disable analytics and enable linux desktop
+    flutter --no-version-check config --no-analytics
+    flutter --no-version-check config --enable-linux-desktop
+
+    # Pull dependencies within prepare, allowing for offline builds later on
+    flutter --no-version-check pub get
+}
+
+build() {
+    cd "$pkgname-$pkgver"
+    flutter --no-version-check build linux --release
+
+    # Copy icon to source directory for installing
+    cp assets/icon/resized/icon-128x128.png ./saber.png
+}
+
+package() {
+    # Build directory for the final executable
+    cd "$pkgname-$pkgver/build/linux/x64/release/bundle/"
+
+    # Install application, licence and desktop file (with assets)
+    install -dm 755 "$pkgdir/opt/$pkgname" "$pkgdir/usr/bin/"
+    cp -rdp --no-preserve=ownership . "$pkgdir/opt/$pkgname/"
+    install -Dm644 "$srcdir/$pkgname-$pkgver/saber.desktop" -t "$pkgdir/usr/share/applications/"
+    install -Dm644 "$srcdir/$pkgname-$pkgver/saber.png" -t "$pkgdir/usr/share/pixmaps/"
+
+    # Symbolic link from package to /usr/bin so it appears within the PATH
+    ln -s "/opt/$pkgname/$pkgname" "$pkgdir/usr/bin/$pkgname"
+}