Initial git version of sdl2-hg

2 files changed, 80 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..954443c465bd
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,35 @@
+pkgbase = sdl2-git
+	pkgdesc = A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)
+	pkgver = release.2.0.14.r347.gf443a6fc7
+	pkgrel = 1
+	url = https://www.libsdl.org
+	arch = x86_64
+	arch = aarch64
+	arch = armv7l
+	license = MIT
+	makedepends = alsa-lib
+	makedepends = mesa
+	makedepends = libpulse
+	makedepends = libxrandr
+	makedepends = libxinerama
+	makedepends = wayland
+	makedepends = libxkbcommon
+	makedepends = wayland-protocols
+	makedepends = ibus
+	makedepends = fcitx
+	makedepends = libxss
+	makedepends = jack
+	makedepends = git
+	depends = libgl
+	depends = libibus
+	optdepends = alsa-lib: ALSA audio driver
+	optdepends = libpulse: PulseAudio audio driver
+	optdepends = jack: JACK audio driver
+	provides = sdl2
+	conflicts = sdl2
+	conflicts = sdl2-minimal-hg
+	source = git+https://github.com/libsdl-org/SDL
+	sha512sums = SKIP
+
+pkgname = sdl2-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..0cc6f49a780d
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: Christer Solskogen <christer.solskogen@gmail.com>
+
+pkgname=sdl2-git
+pkgver=release.2.0.14.r347.gf443a6fc7
+pkgrel=1
+pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2)"
+arch=('x86_64' 'aarch64' 'armv7l')
+url="https://www.libsdl.org"
+license=('MIT')
+depends=('libgl' 'libibus' )
+makedepends=('alsa-lib' 'mesa' 'libpulse' 'libxrandr' 'libxinerama' 'wayland' 'libxkbcommon'
+             'wayland-protocols' 'ibus' 'fcitx' 'libxss' 'jack' 'git' )
+optdepends=('alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver'
+            'jack: JACK audio driver')
+source=("git+https://github.com/libsdl-org/SDL")
+provides=(sdl2)
+conflicts=(sdl2 sdl2-minimal-hg)
+sha512sums=('SKIP')
+
+pkgver() {
+  cd SDL
+  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+	rm -rf build
+	mkdir build
+}
+
+build() {
+	cd build
+	../SDL/configure --prefix=/usr \
+			--disable-video-rpi \
+			--enable-video-kmsdrm
+	make
+}
+
+package() {
+	cd build
+	make install DESTDIR="$pkgdir"
+	install -Dm644 ../SDL/COPYING.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+	chown -R root:root "$pkgdir"
+}
+