initial upload

2 files changed, 63 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..32d442f89b1b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = sdl2_image-minimal-hg
+	pkgdesc = A simple library to load images of various formats as SDL surfaces (Version 2)
+	pkgver = 2.0.5
+	pkgrel = 1
+	url = http://www.libsdl.org/projects/SDL_image
+	arch = x86_64
+	license = MIT
+	makedepends = cmake
+	depends = sdl2
+	depends = libpng
+	depends = libtiff
+	depends = libjpeg
+	provides = sdl2_image
+	conflicts = sdl2_image
+	source = hg+https://hg.libsdl.org/SDL_image/
+	sha512sums = SKIP
+
+pkgname = sdl2_image-minimal-hg
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c1105eee54af
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer:  Vincent Grande <shoober420@gmail.com>
+# Contributor: Sven-Hendrik Haase <sh@lutzhaase.com>
+
+pkgname=sdl2_image-minimal-hg
+pkgver=2.0.5
+pkgrel=1
+pkgdesc="A simple library to load images of various formats as SDL surfaces (Version 2)"
+arch=('x86_64')
+url="http://www.libsdl.org/projects/SDL_image"
+license=('MIT')
+depends=('sdl2' 'libpng' 'libtiff' 'libjpeg')
+makedepends=('cmake')
+provides=(sdl2_image)
+conflicts=(sdl2_image)
+source=(hg+https://hg.libsdl.org/SDL_image/)
+sha512sums=('SKIP')
+
+pkgver() {
+  cd SDL_image
+
+  local _lasttag=$(hg tags -q | sort -r | grep release- | head -n1)
+  local _commits=$(hg log --template "{node}\n" -r $_lasttag:tip | wc -l)
+  printf "%s.r%s.%s" "${_lasttag/release-}" "$_commits" "$(hg identify -i)"
+}
+
+
+build() {
+  cd SDL_image
+  ./configure --disable-static --prefix=/usr \
+    --disable-jpg-shared \
+    --disable-png-shared \
+    --disable-tif-shared \
+    --disable-webp-shared \
+    --disable-webp \
+    --disable-webpdec
+  make
+}
+
+package() {
+  cd SDL_image
+
+  make DESTDIR="${pkgdir}/" install
+  install -Dm644 COPYING.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}