Initial packaging

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..0b9ffdaedd9a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = sear-git
+	pkgdesc = Signed/Encrypted ARchive
+	pkgver = 0.0.0.r38.g1b262d8
+	pkgrel = 1
+	url = https://github.com/iqlusioninc/sear
+	arch = x86_64
+	license = MIT
+	license = Apache
+	makedepends = cargo
+	provides = sear
+	conflicts = sear
+	source = sear-git::git+https://github.com/iqlusioninc/sear.git
+	sha256sums = SKIP
+
+pkgname = sear-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..062e3c97d9cc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: Caleb Maclennnan <caleb@alerque.com>
+
+# TODO:
+# * upstream 0.0.0 released to crates.io but not tagged,
+#   remove forced tag on ba1f37f when rpository gets tagged
+
+pkgname=sear-git
+pkgver=0.0.0.r38.g1b262d8
+pkgrel=1
+pkgdesc="Signed/Encrypted ARchive"
+arch=('x86_64')
+url="https://github.com/iqlusioninc/${pkgname%-git}"
+license=('MIT' 'Apache')
+makedepends=('cargo')
+provides=("${pkgname%-git}")
+conflicts=($provides)
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+  git tag -f 0.0.0 ba1f37f 2>&1 >/dev/null ||:
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "$pkgname"
+  cargo build --release --locked --all-features
+}
+
+package() {
+  cd "$pkgname"
+  install -Dm755 -t "$pkgdir/usr/bin/" "target/release/${pkgname%-git}"
+  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+  install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}