Initial import.

2 files changed, 69 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..52f37cfbbf6a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = shedskin-git
+	pkgdesc = Experimental (restricted) Python-to-C++ compiler (development version)
+	pkgver = latest
+	pkgrel = 1
+	url = http://code.google.com/p/shedskin/
+	arch = any
+	license = GPL3
+	makedepends = git
+	makedepends = python2
+	depends = pcre
+	depends = gc
+	depends = python2
+	provides = shedskin
+	conflicts = shedskin
+	source = shedskin::git+https://gitorious.org/shedskin/mainline.git
+	sha256sums = SKIP
+
+pkgname = shedskin-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..df5f1f7feb90
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,50 @@
+# Maintainer: Bjorn Neergaard (neersighted) <bjorn@neersighted.com>
+# Contributor: Elkin Cruz <agnelkincc@gmail.com>
+# Contributor: Alexander Rødseth <rodseth@gmail.com>
+
+_pkgname=shedskin
+pkgname=shedskin-git
+pkgver=latest
+pkgrel=1
+pkgdesc='Experimental (restricted) Python-to-C++ compiler (development version)'
+url='http://code.google.com/p/shedskin/'
+license=('GPL3')
+source=("${_pkgname}::git+https://gitorious.org/shedskin/mainline.git")
+sha256sums=('SKIP')
+arch=('any')
+depends=('pcre' 'gc' 'python2')
+makedepends=('git' 'python2')
+conflicts=('shedskin')
+provides=('shedskin')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+
+  # Get the version number.
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd "${srcdir}/${_pkgname}"
+
+  # Patch Python versions.
+  sed -i -e 's/python\b/python2/g' $(grep -rl 'python\b')
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+
+  # Build it!
+  python2 setup.py build
+}
+
+package() {
+  cd "${srcdir}/${_pkgname}"
+
+  # Install the program.
+  python2 setup.py install \
+    --root="${pkgdir}" \
+    --prefix=/usr
+}
+
+# vim: ft=sh ts=2 sw=2 et