addpkg: sheldon 0.6.4-1

2 files changed, 68 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..7cf6352cfd6b
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,16 @@
+pkgbase = sheldon
+	pkgdesc = A fast and configurable shell plugin manager
+	pkgver = 0.6.4
+	pkgrel = 1
+	url = https://sheldon.cli.rs
+	arch = x86_64
+	license = Apache
+	license = MIT
+	makedepends = git
+	makedepends = rust
+	makedepends = mdbook-linkcheck
+	depends = curl
+	source = git+https://github.com/rossmacarthur/sheldon.git#commit=34a71135a1aa097da6fedde1b16a0ae222244a46
+	b2sums = SKIP
+
+pkgname = sheldon
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..49ace4cb9eef
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,52 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+
+pkgname=sheldon
+pkgver=0.6.4
+pkgrel=1
+pkgdesc="A fast and configurable shell plugin manager"
+arch=('x86_64')
+url="https://sheldon.cli.rs"
+license=('Apache' 'MIT')
+depends=('curl')
+makedepends=('git' 'rust' 'mdbook-linkcheck')
+_commit='34a71135a1aa097da6fedde1b16a0ae222244a46'
+source=("git+https://github.com/rossmacarthur/sheldon.git#commit=$_commit")
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgname"
+  git describe --tags | sed 's/^[vV]//;s/-/+/g'
+}
+
+prepare() {
+  cd "$pkgname"
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+  cd "$pkgname"
+
+  # binary
+  cargo build --frozen --release --all-features
+
+  # documentation
+  mdbook build docs
+}
+
+check() {
+  cd "$pkgname"
+  cargo test --frozen --all-features
+}
+
+package() {
+  cd "$pkgname"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/sheldon
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE*
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" *.md
+}