init

2 files changed, 94 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..a07850d85be9
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,29 @@
+pkgbase = sonic-visualiser-hg
+	pkgdesc = A viewer and analyser of music audio files. (hg version)
+	pkgver = r1755.c866f9a77b23
+	pkgrel = 1
+	url = http://www.sonicvisualiser.org/
+	arch = x86_64
+	license = GPL2
+	makedepends = mercurial
+	makedepends = git
+	makedepends = mlton
+	depends = capnproto-git
+	depends = libfishsound
+	depends = libid3tag
+	depends = liblo
+	depends = liblrdf
+	depends = libmad
+	depends = liboggz
+	depends = libpulse
+	depends = portaudio
+	depends = qt5-svg
+	depends = rubberband
+	depends = sord
+	depends = hicolor-icon-theme
+	provides = sonic-visualiser
+	source = hg+https://code.soundsoftware.ac.uk/hg/sonic-visualiser
+	md5sums = SKIP
+
+pkgname = sonic-visualiser-hg
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..2f0f627a943f
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Maintainer: Teteros <teteros at teknik dot io>
+
+_pkgname=sonic-visualiser
+pkgname=sonic-visualiser-hg
+pkgver=r1755.c866f9a77b23
+pkgrel=1
+pkgdesc="A viewer and analyser of music audio files. (hg version)"
+arch=('x86_64')
+url="http://www.sonicvisualiser.org/"
+license=('GPL2')
+depends=('capnproto-git' 'libfishsound' 'libid3tag' 'liblo'
+'liblrdf' 'libmad' 'liboggz' 'libpulse' 'portaudio' 'qt5-svg'
+'rubberband' 'sord' 'hicolor-icon-theme')
+makedepends=('mercurial' 'git' 'mlton')
+provides=("${pkgname%-hg}")
+source=("hg+https://code.soundsoftware.ac.uk/hg/$_pkgname")
+md5sums=('SKIP')
+
+pkgver() {
+    cd "$_pkgname"
+    printf "r%s.%s" "$(hg identify -n)" "$(hg identify -i)"
+}
+
+#prepare() {
+#    cd "$_pkgname"
+#    autoreconf -vi
+#}
+
+build() {
+    cd "$_pkgname"
+    ./configure --prefix=/usr
+    make
+}
+
+package() {
+    cd "$_pkgname"
+    INSTALL_ROOT="$pkgdir" make install
+
+    # vamp binaries
+    install -Dm755 vamp-plugin-load-checker "$pkgdir/usr/bin/vamp-plugin-load-checker"
+    install -Dm755 piper-vamp-simple-server "$pkgdir/usr/bin/piper-vamp-simple-server"
+
+    # desktop files
+    install -t "$pkgdir/usr/share/applications" -Dm644 *.desktop
+
+    # icons
+    for _s in 16 22 24 32 48 64 128; do
+        install -Dm644 icons/sv-${_s}x${_s}.png \
+            "$pkgdir/usr/share/icons/hicolor/${_s}x${_s}/apps/sv-icon.png"
+    done
+    install -Dm644 icons/sv-icon.svg \
+        "$pkgdir/usr/share/icons/hicolor/scalable/apps/sv-icon.svg"
+
+    # samples
+    install -t "$pkgdir/usr/share/$pkgname/samples" -Dm644 samples/*
+
+    # templates
+    install -t "$pkgdir/usr/share/$pkgname/templates" -Dm644 templates/*
+
+    # docs
+    install -Dm644 CHANGELOG "$pkgdir/usr/share/doc/$pkgname/CHANGELOG"
+    install -Dm644 CITATION "$pkgdir/usr/share/doc/$pkgname/CITATION"
+    install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
+    install -Dm644 README.OSC "$pkgdir/usr/share/doc/$pkgname/README.osc"
+}