Initialize

2 files changed, 65 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..20f4dd740034
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,22 @@
+pkgbase = souk-git
+	pkgdesc = Independent Flatpak App Store
+	pkgver = r262.9381b9f
+	pkgrel = 1
+	url = https://gitlab.gnome.org/haecker-felix/souk
+	arch = i686
+	arch = x86_64
+	arch = armv7h
+	arch = aarch64
+	license = GPL3
+	makedepends = git
+	makedepends = meson
+	depends = flatpak
+	depends = gtk4
+	depends = libadwaita
+	provides = souk
+	conflicts = souk
+	source = git+https://gitlab.gnome.org/haecker-felix/souk.git
+	md5sums = SKIP
+
+pkgname = souk-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..6a0568e11ce6
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,43 @@
+# Maintainer: Philip Goto <philip.goto@gmail.com>
+
+pkgname=souk-git
+pkgver=r262.9381b9f
+pkgrel=1
+pkgdesc="Independent Flatpak App Store"
+arch=(i686 x86_64 armv7h aarch64)
+url="https://gitlab.gnome.org/haecker-felix/souk"
+license=(GPL3)
+depends=(
+	flatpak
+	gtk4
+	libadwaita
+)
+makedepends=(
+	git
+	meson
+)
+provides=(souk)
+conflicts=(souk)
+source=("git+${url}.git")
+md5sums=(SKIP)
+
+pkgver() {
+	cd souk
+	( set -o pipefail
+		git describe --long --tags 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
+		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+build() {
+	arch-meson souk build -Dtests=false
+	meson compile -C build
+}
+
+check() {
+	meson test -C build --print-errorlogs
+}
+
+package() {
+	DESTDIR="${pkgdir}" meson install -C build
+}