feat: add initial version

2 files changed, 52 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..9d9b82241e77
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = soundsense-rs-git
+	pkgdesc = A Rust version of SoundSense
+	pkgver = 1.5.1.travis.r8.g055acfb
+	pkgrel = 1
+	url = https://github.com/prixt/soundsense-rs
+	arch = x86_64
+	license = MIT
+	makedepends = rust
+	makedepends = alsa-lib
+	makedepends = gtk3
+	makedepends = webkit2gtk
+	source = git+https://github.com/prixt/soundsense-rs.git
+	md5sums = SKIP
+
+pkgname = soundsense-rs-git
+	depends = libasound.so
+	depends = libgtk-3.so
+	depends = libgdk-3.so
+	depends = libwebkit2gtk-4.0.so
+	depends = libjavascriptcoregtk-4.0.so
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..b3b468c7c060
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,31 @@
+# Maintainer: imtbl <imtbl at mser dot at>
+pkgname=soundsense-rs-git
+_pkgname=soundsense-rs
+pkgver=1.5.1.travis.r8.g055acfb
+pkgrel=1
+pkgdesc="A Rust version of SoundSense"
+arch=('x86_64')
+url="https://github.com/prixt/${_pkgname}"
+license=('MIT')
+makedepends=('rust' 'alsa-lib' 'gtk3' 'webkit2gtk')
+source=("git+https://github.com/prixt/${_pkgname}.git")
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${srcdir}/${_pkgname}"
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${srcdir}/${_pkgname}"
+  cargo build --release --locked
+}
+
+package() {
+  depends+=('libasound.so' 'libgtk-3.so' 'libgdk-3.so' 'libwebkit2gtk-4.0.so'
+            'libjavascriptcoregtk-4.0.so')
+
+  cd "${srcdir}/${_pkgname}"
+  install -Dm755 "target/release/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}