Initial commit

2 files changed, 57 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..310fd9fd2454
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,19 @@
+pkgbase = spivak-git
+	pkgdesc = Karaoke player based on GStreamer and Qt5 (git)
+	pkgver = r174.2507040
+	pkgrel = 1
+	url = https://github.com/gyunaev/spivak
+	arch = x86_64
+	license = GPL3
+	makedepends = git
+	depends = gst-plugins-base
+	depends = libzip
+	depends = qt5-base
+	depends = uchardet
+	provides = spivak
+	conflicts = spivak
+	source = spivak-git::git+https://github.com/gyunaev/spivak.git
+	sha256sums = SKIP
+
+pkgname = spivak-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..bf2eecac1fdc
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Jose Riha <jose1711 gmail com>
+
+pkgname=spivak-git
+pkgver=r174.2507040
+pkgrel=1
+pkgdesc="Karaoke player based on GStreamer and Qt5 (git)"
+arch=(x86_64)
+url="https://github.com/gyunaev/spivak"
+license=(GPL3)
+depends=(gst-plugins-base libzip qt5-base uchardet)
+makedepends=(git)
+source=("${pkgname}"::"git+https://github.com/gyunaev/spivak.git")
+conflicts=('spivak')
+provides=('spivak')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "$srcdir/${pkgname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd $pkgname
+  sed -i '/SUBDIRS += languagedetector/d' plugins/plugins.pro
+}
+
+build() {
+  cd $pkgname
+  qmake
+  make
+}
+
+package() {
+  cd $pkgname
+  install -Dm755 src/spivak "$pkgdir/usr/bin/spivak"
+  install -Dm644 packaging/spivak.desktop "$pkgdir/usr/share/applications/spivak.desktop"
+  install -Dm644 packaging/icon.png "$pkgdir/usr/share/pixmaps/spivak.png"
+}