Initial commit

2 files changed, 61 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..6225f8639d21
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,17 @@
+pkgbase = sprite-sheet-packer-git
+	pkgdesc = Sprite sheet packer not unlike TexturePacker
+	pkgver = 1.0.9.r19.g6fc0ee6
+	pkgrel = 1
+	url = https://github.com/amakaseev/sprite-sheet-packer/
+	arch = x86_64
+	license = MIT
+	makedepends = git
+	makedepends = gendesk
+	depends = qt5-declarative
+	provides = sprite-sheet-packer
+	conflicts = sprite-sheet-packer
+	source = git+https://github.com/amakaseev/sprite-sheet-packer.git
+	md5sums = SKIP
+
+pkgname = sprite-sheet-packer-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..c30ce8bf1179
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,44 @@
+# Maintainer: rouhannb <rouhannb at gmail dot com> 
+pkgname=sprite-sheet-packer-git
+pkgver=1.0.9.r19.g6fc0ee6
+pkgrel=1
+pkgdesc='Sprite sheet packer not unlike TexturePacker'
+arch=('x86_64')
+url='https://github.com/amakaseev/sprite-sheet-packer/'
+license=('MIT')
+depends=('qt5-declarative')
+makedepends=('git' 'gendesk')
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=('git+https://github.com/amakaseev/sprite-sheet-packer.git')
+md5sums=('SKIP')
+
+# Gendesk info
+_name='SpriteSheet Packer'
+_exec='SpriteSheetPacker'
+_categories='Development;Graphics;2DGraphics;RasterGraphics;Qt'
+
+prepare() {
+	gendesk -f -n
+}
+
+pkgver() {
+	cd "$srcdir/${pkgname%-git}"
+	git describe --long --tags | sed 's/-/.r/;s/-/./'
+}
+
+build() {
+	cd "$srcdir/${pkgname%-git}/SpriteSheetPacker"
+	qmake
+	sed -i '/\$(TARGET):/!b;n;n;n;d' Makefile
+	make
+}
+
+package() {
+	cd "$srcdir/${pkgname%-git}"
+	install -D -t "$pkgdir/usr/lib" "SpriteSheetPacker/3rdparty/PVRTexTool/Linux_$CARCH/libPVRTexLib.so"
+	install -D -t "$pkgdir/usr/bin" 'install/linux/bin/SpriteSheetPacker'
+	install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm644 -t "$pkgdir/usr/share/applications" "$srcdir/${pkgname%-git}.desktop"
+	install -Dm644 'SpriteSheetPacker/res/icon.png' "$pkgdir/usr/share/pixmaps/${pkgname%-git}.png"
+}