Init

3 files changed, 73 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..44e85e411960
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,18 @@
+pkgbase = stratisd-git
+	pkgdesc = Stratis is a new tool that meets the needs of Red Hat Enterprise Linux (RHEL) users calling for an easily configured, tightly integrated solution for storage that works within the existing Red Hat storage management stack.
+	pkgver = 0.1.0.r7.g9204a4d
+	pkgrel = 1
+	url = https://stratis-storage.github.io/
+	arch = i686
+	arch = x86_64
+	license = MPL2
+	makedepends = cargo
+	makedepends = git
+	makedepends = rust
+	provides = stratisd
+	conflicts = stratisd
+	source = git+https://github.com/stratis-storage/stratisd.git
+	sha256sums = SKIP
+
+pkgname = stratisd-git
+
diff --git a/.gitignore b/.gitignore
new file mode 100644
index 000000000000..9865d22ba8ed
--- /dev/null
+++ b/.gitignore
@@ -0,0 +1,7 @@
+# Blacklist:
+*
+
+# Whitelist:
+!.gitignore
+!PKGBUILD
+!.SRCINFO
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..66e3494c6751
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,48 @@
+# Maintainer: Dan Beste <dan.ray.beste@gmail.com>
+
+# TODO: Include docs!
+
+pkgname='stratisd-git'
+_gitname='stratisd'
+pkgver=0.1.0.r7.g9204a4d
+pkgrel=1
+pkgdesc='Stratis is a new tool that meets the needs of Red Hat Enterprise Linux (RHEL) users calling for an easily configured, tightly integrated solution for storage that works within the existing Red Hat storage management stack.'
+arch=('i686' 'x86_64')
+url='https://stratis-storage.github.io/'
+license=('MPL2')
+makedepends=('cargo' 'git' 'rust')
+provides=("${_gitname}")
+conflicts=("${_gitname}")
+source=('git+https://github.com/stratis-storage/stratisd.git')
+sha256sums=('SKIP')
+
+pkgver() {
+  cd "${_gitname}"
+
+  git describe --long --tags \
+    | sed 's/v//'            \
+    | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cd "${_gitname}"
+
+  cargo build --release
+}
+
+check() {
+  cd "${_gitname}"
+
+  make test
+}
+
+package() {
+  cd "${_gitname}"
+
+  install -D -m 755 \
+    target/release/${_gitname} "${pkgdir}/usr/bin/${_gitname}"
+  install -D -m 644 \
+    LICENSE "${pkgdir}/usr/share/licenses/${_gitname}/LICENSE"
+}
+
+# vim: ts=2 sw=2 et: