Initial bringup

2 files changed, 67 insertions, 0 deletions

diff --git a/.SRCINFO b/.SRCINFO
new file mode 100644
index 000000000000..8d72c77d1e8a
--- /dev/null
+++ b/.SRCINFO
@@ -0,0 +1,21 @@
+pkgbase = swftools-git
+	pkgdesc = Utilities for editing and generating Adobe Flash (SWF) files
+	pkgver = r5100.eeede5d8
+	pkgrel = 1
+	url = https://github.com/matthiaskramm/swftools
+	arch = x86_64
+	license = GPL
+	makedepends = git
+	depends = libjpeg-turbo
+	depends = giflib
+	depends = fontconfig
+	depends = fftw
+	depends = pdflib-lite
+	depends = zziplib
+	provides = swftools
+	conflicts = swftools
+	source = git+https://github.com/matthiaskramm/swftools
+	md5sums = SKIP
+
+pkgname = swftools-git
+
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 000000000000..d331e30b8517
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,46 @@
+# Maintainer: Robin Broda <robin at broda dot me>
+
+_pkgname="swftools"
+pkgname=("${_pkgname}-git")
+pkgver=r5100.eeede5d8
+pkgrel=1
+pkgdesc='Utilities for editing and generating Adobe Flash (SWF) files'
+arch=('x86_64')
+url='https://github.com/matthiaskramm/swftools'
+license=('GPL')
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+depends=('libjpeg-turbo' 'giflib' 'fontconfig' 'fftw' 'pdflib-lite' 'zziplib')
+makedepends=('git')
+source=('git+https://github.com/matthiaskramm/swftools')
+md5sums=('SKIP')
+
+pkgver() {
+  cd "${_pkgname}"
+  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+prepare() {
+  cd "${_pkgname}"
+
+  ./configure --prefix=/usr
+}
+
+build() {
+  cd "${_pkgname}"
+
+  # Work around https://github.com/matthiaskramm/swftools/issues/12
+  make || make
+}
+
+package() {
+  cd "${_pkgname}"
+
+  make prefix="${pkgdir}/usr" install
+
+  # Fix invalid symlinks referencing pkgdir
+  cd "${pkgdir}/usr/share/${_pkgname}/swfs"
+  rm -f default_loader.swf default_viewer.swf
+  ln -s tessel_loader.swf default_loader.swf
+  ln -s simple_viewer.swf default_viewer.swf
+}